**Обзор полезных методов БСП 3.1.4. Часть 2**

**Библиотека стандартных подсистем (далее - БСП) является частью любой типовой конфигурации, поэтому умение применять готовые процедуры и функции повышает качество разработки и избавляет от написания лишнего кода. К сожалению, не у всех есть время и упорство овладеть всей документацией, поэтому я собрал воедино наиболее популярный функционал.**

**Как велась подготовка материала**

Официальная документация неплохо структурирована и подробно описывает каждый метод. Единственная трудность, с которой я столкнулся, было незнание, какие методы наиболее популярны в основных типовых решениях. Что необходимо знать в первую очередь, а какой функционал оставить на потом. Цель статьи - собрать и упорядочить методы по популярности (суммарным количеством вызовов). Что было сделано:

1. Из официальной документации получены все вызовы (за исключением раздела "Предопределенные").

2. Далее, производился поиск и подсчет каждого метода в 5-х типовых конфигурациях: УТ 11.4, РТ 2.3, БП 3.0, ЗУП 3.1 и ERP 2.4.

3. В заключение, собранная статистика вызовов была преобразована в разделы, близкие по структуре с документацией, и упорядочена в порядке убывания по количеству вызовов. Тем самым мы сразу можем увидеть методы, которые используются наиболее часто. Для удобства ряд методов в рамках раздела сгруппирован логически. Порядок разделов выполнен в ручном режиме. Цифра перед именем метода это и есть количество вызовов данного метода.

Часть 1. [Базовая функциональность](https://infostart.ru/1c/articles/1398340/).

**Часть 2. Остальные разделы**

**Пользователи**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6Mjk0Omhkb2M=)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQwJUJGJUQwJUJFJUQwJUJCJUQxJThDJUQwJUI3JUQwJUJFJUQwJUIyJUQwJUIwJUQxJTgyJUQwJUI1JUQwJUJCJUQwJUI4)

2259. [**ТекущийПользователь**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Ll6vP56Onv7uv85+7i4PLl6/wuaHRtIw==). Возвращает текущего пользователя.

// Вызов с клиента

Объект.Ответственный = ПользователиКлиент.ТекущийПользователь();

// Вызов с сервера

Объект.Ответственный = Пользователи.ТекущийПользователь();

1926. [**ЭтоПолноправныйПользователь**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/3y7u/u6+3u7/Dg4u376e/u6/zn7uLg8uXr/C5odG0j). Проверяет, является ли текущий или указанный пользователь полноправным.

Если Не Пользователи.ЭтоПолноправныйПользователь() Тогда

ВызватьИсключение НСтр("ru = 'Недостаточно прав для совершения операции.'");

КонецЕсли;

// пример вызова с клиента, конфигурация ERP

Результат = ОбщегоНазначенияУТВызовСервера.ЭтоПолноправныйПользователь()

981. [**АвторизованныйПользователь**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+Di8u7w6Ofu4uDt7fvp7+7r/Ofu4uDy5ev8Lmh0bSM=). Возвращает текущего пользователя или текущего внешнего пользователя, в зависимости от того, кто выполнил вход в сеанс.

// Вызов с клиента

Результат = ПользователиКлиент.АвторизованныйПользователь()

// Вызов с сервера

Результат = Пользователи.АвторизованныйПользователь()

620. [**РолиДоступны**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Du6+jk7vHy8+/t+y5odG0j). Возвращает доступность хотя бы одной из указанных ролей или полноправность пользователя (текущего или указанного).

Результат = Пользователи.РолиДоступны(ИменаРолей, Пользователь, УчитыватьПривилегированныйРежим)

//

РолиДоступны = Пользователи.РолиДоступны("ПолныеПрава, БазовыеПрава");

143. [**ВходВПрограммуРазрешен**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+L17uTi7/Du4/Dg7Ozz8ODn8OX45e0uaHRtIw==). Проверяет наличие хотя бы одного вида аутентификации у пользователя ИБ.

Результат = Пользователи.ВходВПрограммуРазрешен(ОписаниеПользователяИБ)

//

Процедура ОчиститьРеквизитВходВПрограммуРазрешенУВсехПользователей()

ПользователиИБ = ПользователиИнформационнойБазы.ПолучитьПользователей();

Для Каждого ПользовательИБ Из ПользователиИБ Цикл

Если Пользователи.ВходВПрограммуРазрешен(ПользовательИБ) Тогда

ПользовательИБ.АутентификацияСтандартная = Ложь;

ПользовательИБ.Записать();

КонецЕсли;

КонецЦикла;

КонецПроцедуры

140. [**СсылкаНеуказанногоПользователя**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Hx++vq4O3l8+rg5+Dt7e7j7u/u6/zn7uLg8uXr/y5odG0j). Возвращает ссылку неуказанного пользователя.

Результат = Пользователи.СсылкаНеуказанногоПользователя(СоздатьЕслиНеСуществует)

//

Процедура ОповеститьВсехПользователей()

Запрос = Новый Запрос;

Запрос.Текст = "ВЫБРАТЬ

| Пользователи.ИдентификаторПользователяИБ КАК ИдентификаторПользователяИБ

|ИЗ

| Справочник.Пользователи КАК Пользователи

|ГДЕ

| Пользователи.Ссылка <> &ПользовательНеУказан";

Запрос.УстановитьПараметр("ПользовательНеУказан", Пользователи.СсылкаНеуказанногоПользователя());

ТаблицаВыборки = Запрос.Выполнить().Выгрузить();

ДобавитьСообщениеВСистемуВзаимодействия(ТаблицаВыборки.ВыгрузитьКолонку("ИдентификаторПользователяИБ"));

КонецПроцедуры

100. [**СвойстваПользователяИБ**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Hi7unx8uLg7+7r/Ofu4uDy5ev/6OEuaHRtIw==). Возвращает свойства пользователя информационной базы в виде структуры.

Результат = Пользователи.СвойстваПользователяИБ(ИмяИлиИдентификатор)

//

ТекущийПользователь = Пользователи.АвторизованныйПользователь();

ИдентификаторПользователя = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(ТекущийПользователь, "ИдентификаторПользователяИБ");

СвойстваПользователя = Пользователи.СвойстваПользователяИБ(ИдентификаторПользователя);

21. [**НайтиПоИмени**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+3g6fLo7+7o7OXt6C5odG0j). Возвращает пользователя из справочника Пользователи, с которым сопоставлен пользователь ИБ с указанным именем.

Результат = Пользователи.НайтиПоИмени(ИмяДляВхода)

//

Процедура ПроверитьПолныеПрава(СтрПользователь) Экспорт

ТекПользователь = Пользователи.НайтиПоИмени(СтрПользователь);

Если ТекПользователь = Неопределено Тогда

ОбщегоНазначенияКлиентСервер.СообщитьПользователю(

СтрШаблон(НСтр("ru = 'Пользователь %1 отсутствует в информационной базе!'"), СтрПользователь));

КонецЕсли;

КонецПроцедуры

67. [**НовоеОписаниеПользователяИБ**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+3u4u7l7u/o8eDt6OXv7uv85+7i4PLl6//o4S5odG0j). Возвращает пустую структуру описания пользователя ИБ. Назначение свойств структуры соответствует свойствам объекта ПользовательИнформационнойБазы.

Результат = Пользователи.НовоеОписаниеПользователяИБ()

//

Процедура СоздатьСлужебногоПользователяОповещенийЭДО() Экспорт

ОписаниеПользователяИБ = Пользователи.НовоеОписаниеПользователяИБ();

ОписаниеПользователяИБ.Имя = Логин;

ОписаниеПользователяИБ.ПолноеИмя = НСтр("ru='Бот 1С-ЭДО'");

ОписаниеПользователяИБ.АутентификацияСтандартная = Истина;

ОписаниеПользователяИБ.ПоказыватьВСпискеВыбора = Ложь;

ОписаниеПользователяИБ.Вставить("Действие", "Записать");

ОписаниеПользователяИБ.Вставить("ВходВПрограммуРазрешен", Истина);

ОписаниеПользователяИБ.ЗапрещеноИзменятьПароль = Истина;

ОписаниеПользователяИБ.Пароль = Пароль;

ОписаниеПользователяИБ.Роли = Новый Массив;

ОписаниеПользователяИБ.Роли.Добавить(Метаданные.Роли.ИспользованиеУведомленийЭДО.Имя);

НовыйПользователь = Справочники.Пользователи.СоздатьЭлемент();

НовыйПользователь.Наименование = ОписаниеПользователяИБ.ПолноеИмя;

НовыйПользователь.Служебный = Истина;

НовыйПользователь.ДополнительныеСвойства.Вставить("ОписаниеПользователяИБ", ОписаниеПользователяИБ);

НовыйПользователь.Записать();

КонецПроцедуры

10. [**УдалитьПользователяИБ**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Pk4Ovo8vzv7uv85+7i4PLl6//o4S5odG0j). Удаляет указанного пользователя информационной базы.

Пользователи.УдалитьПользователяИБ(ИмяИлиИдентификатор)

//

&НаСервере

Процедура УдалитьПользователяИБ(ИдентификаторПользователяИБ, Отказ)

Попытка

Пользователи.УдалитьПользователяИБ(ИдентификаторПользователяИБ);

Исключение

ОбщегоНазначенияКлиентСервер.СообщитьПользователю(КраткоеПредставлениеОшибки(ИнформацияОбОшибке()), , , , Отказ);

КонецПопытки;

КонецПроцедуры

7. [**СоздатьАдминистратора**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Hu5+Tg8vzg5Ozo7ejx8vDg8u7w4C5odG0j). Используется при обновлении и начальном заполнении информационной базы. Создает первого администратора и сопоставляет его с новым или существующим пользователем в справочнике Пользователи

Результат = Пользователи.СоздатьАдминистратора(ПользовательИБ)

//

&НаСервере

Процедура ЗаписатьПользователяСервер()

ОписаниеПользователяИБ = Новый Структура;

Если Не ТекущийПользователь.Пустая()

И Справочники.Пользователи.НайтиПоНаименованию("<Не указан>") <> Неопределено

И Справочники.Пользователи.НайтиПоНаименованию("<Не указан>") <> ТекущийПользователь Тогда

Пользователь = ТекущийПользователь.ПолучитьОбъект();

Иначе

ПользовательИБ = ПользователиИнформационнойБазы.НайтиПоИмени(НаименованиеПользователя);

Если ПользовательИБ = Неопределено Тогда

ПользовательИБ = ПользователиИнформационнойБазы.СоздатьПользователя();

ПользовательИБ.Имя = ПользовательИнфБазыИмя;

ПользовательИБ.ПолноеИмя = НаименованиеПользователя;

ПользовательИБ.Пароль = Пароль;

ПользовательИБ.Роли.Очистить();

ПользовательИБ.Роли.Добавить(Метаданные.Роли.ПолныеПрава);

РольАдминистратораСистемы = Метаданные.Роли.АдминистраторСистемы;

Если НЕ ПользовательИБ.Роли.Содержит(РольАдминистратораСистемы) Тогда

ПользовательИБ.Роли.Добавить(РольАдминистратораСистемы);

КонецЕсли;

ПользовательИБ.Записать();

КонецЕсли;

ОписаниеПользователяИБ.Вставить("Действие", "Записать");

ОписаниеПользователяИБ.Вставить(

"УникальныйИдентификатор", ПользовательИБ.УникальныйИдентификатор);

// Пользователи.СоздатьАдминистратора

Пользователь = Пользователи.СоздатьАдминистратора(ПользовательИБ);

КонецЕсли;

ТекущийПользователь = Пользователь.Ссылка;

КонецПроцедуры

5. [**СоздатьПароль**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Hu5+Tg8vzv4PDu6/wuaHRtIw==). Создает новый пароль, соответствующий заданным правилам проверки сложности. Для облегчения запоминания, пароль формируется из слогов (согласная-гласная).

Результат = Пользователи.СоздатьПароль(НаименьшаяДлина, Сложный, УчестьНастройки)

//

НовыйПароль = Пользователи.СоздатьПароль(8, Истина);

5. [**СохраняемоеЗначениеСтрокиПароля**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Hu9fDg7f/l7O7l5+3g9+Xt6OXx8vDu6ujv4PDu6/8uaHRtIw==). Возвращает сохраняемое значение пароля для указанного пароля.

Результат = Пользователи.СохраняемоеЗначениеСтрокиПароля(Пароль)

30. [**СкопироватьСвойстваПользователяИБ**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Hq7u/o8O7i4PL88eLu6fHy4uDv7uv85+7i4PLl6//o4S5odG0j). Копирует значения свойств пользователя ИБ с преобразованием в/из строковых идентификаторов для основного интерфейса, языка, режима запуска и ролей.

Пользователи.СкопироватьСвойстваПользователяИБ(Приемник, Источник, КопируемыеСвойства, ИсключаемыеСвойства, ПрефиксСвойств)

77. [**НайтиНеоднозначныхПользователейИБ**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+3g6fLo7eXu5O3u5+3g9+379e/u6/zn7uLg8uXr5eno4S5odG0j). Выполняет поиск идентификаторов пользователей ИБ, используемых более одного раза, и либо вызывает исключение, либо возвращает найденных пользователей ИБ для дальнейшей обработки.

Пользователи.НайтиНеоднозначныхПользователейИБ(Пользователь, УникальныйИдентификатор,

НайденныеИдентификаторы, ИдентификаторПользователяСервиса)

15. [**СформироватьДанныеВыбораПользователя**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/H07vDs6PDu4uDy/OTg7e375eL74e7w4O/u6/zn7uLg8uXr/y5odG0j). Возвращает список пользователей, групп пользователей, внешних пользователей и групп внешних пользователей. Для использования в обработчиках событий ОкончаниеВводаТекста и АвтоПодбор.

Результат = Пользователи.СформироватьДанныеВыбораПользователя(Текст, ВключаяГруппы, ВключаяВнешнихПользователей, БезПользователей)

//

&НаКлиенте

Процедура ПользователиПолноеПредставлениеОкончаниеВводаТекста(Элемент, Текст, ДанныеВыбора, СтандартнаяОбработка)

Если ЗначениеЗаполнено(Текст) Тогда

СтандартнаяОбработка = Ложь;

ДанныеВыбора = СформироватьДанныеВыбораПользователя(Текст);

КонецЕсли;

КонецПроцедуры

&НаСервереБезКонтекста

Функция СформироватьДанныеВыбораПользователя(Знач Текст,

Знач ВключаяГруппы = Истина,

Знач ВключаяВнешнихПользователей = Неопределено,

Знач БезПользователей = Ложь)

Возврат Пользователи.СформироватьДанныеВыбораПользователя(

Текст,

ВключаяГруппы,

ВключаяВнешнихПользователей,

БезПользователей);

КонецФункции

5. [**ПользовательИБЗанят**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/u6/zn7uLg8uXr/Ojh5+Dt//IuaHRtIw==). Проверяет, сопоставлен ли пользователь ИБ с элементом справочника Пользователи или с элементом справочника ВнешниеПользователи.

Результат = Пользователи.ПользовательИБЗанят(ПользовательИБ, УчетнаяЗапись)

//

Функция СсылкаПользователяПоПолномуНаименованию(ПолноеИмя)

УстановитьПривилегированныйРежим(Истина);

Запрос = Новый Запрос;

Запрос.Текст =

"ВЫБРАТЬ

| Пользователи.Ссылка КАК Ссылка,

| Пользователи.ИдентификаторПользователяИБ

|ИЗ

| Справочник.Пользователи КАК Пользователи

|ГДЕ

| Пользователи.Наименование = &ПолноеИмя";

Запрос.УстановитьПараметр("ПолноеИмя", ПолноеИмя);

РезультатЗапроса = Запрос.Выполнить();

Если НЕ РезультатЗапроса.Пустой() Тогда

Выборка = РезультатЗапроса.Выбрать();

Выборка.Следующий();

Если НЕ Пользователи.ПользовательИБЗанят(Выборка.ИдентификаторПользователяИБ) Тогда

Результат = Выборка.Ссылка;

КонецЕсли;

КонецЕсли;

Возврат Результат;

КонецФункции

**Печать**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6Mjg5Omhkb2M=)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQwJUJGJUQwJUI1JUQxJTg3JUQwJUIwJUQxJTgyJUQxJThD)

1435. [**ВывестиТабличныйДокументВКоллекцию**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+L74uXx8ujy4OHr6Pft++nk7urz7OXt8uLq7uvr5er26P4uaHRtIw==). Добавляет табличный документ в коллекцию печатных форм. Процедура предназначена для использования только внутри процедуры Печать.

УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, ИмяМакета, СинонимМакета, ТабличныйДокумент, Картинка, ПолныйПутьКМакету, ИмяФайлаПечатнойФормы)

// Модуль менеджера документа

Процедура Печать(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт

Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "Накладная") Тогда

УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(

КоллекцияПечатныхФорм,

"Накладная",

НСтр("ru = 'Реализация товаров'"),

СформироватьПечатнуюФормуНакладная(МассивОбъектов, ОбъектыПечати, ПараметрыПечати),

,

"Документ.РеализацияТоваровУслуг.ПФ\_MXL\_РеализацияТоваров");

КонецЕсли;

КонецПроцедуры

1307. [**НужноПечататьМакет**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+3z5u3u7+X34PLg8vzs4Orl8i5odG0j). Проверить, нужно ли печатать макет. Функция предназначена для использования только внутри процедуры Печать.

Результат = УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, ИмяМакета)

// Модуль менеджера документа

Процедура Печать(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт

Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "Накладная") Тогда

УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(

КоллекцияПечатныхФорм,

"Накладная",

НСтр("ru = 'Реализация товаров'"),

СформироватьПечатнуюФормуНакладная(МассивОбъектов, ОбъектыПечати, ПараметрыПечати),

,

"Документ.РеализацияТоваровУслуг.ПФ\_MXL\_РеализацияТоваров");

КонецЕсли;

КонецПроцедуры

1121. [**МакетПечатнойФормы**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+zg6uXy7+X34PLt7un07vDs+y5odG0j). Возвращает макет печатной формы по полному пути к макету.

Результат = УправлениеПечатью.МакетПечатнойФормы(ПутьКМакету, КодЯзыка)

//

Макет = УправлениеПечатью.МакетПечатнойФормы("ОбщийМакет.ПФ\_MXL\_РасчетныйЛистокДляСервисаКабинетСотрудника");

Макет = УправлениеПечатью.МакетПечатнойФормы("Справочник.Организации." + ИмяМакета);

868. [**ЗадатьОбластьПечатиДокумента**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+fg5ODy/O7h6+Dx8vzv5ffg8ujk7urz7OXt8uAuaHRtIw==). Задает область печати объекта в табличном документе.

Пока ВыборкаПоДокументам.Следующий() Цикл

НомерСтрокиНачало = ТабличныйДокумент.ВысотаТаблицы + 1;

// ... вывод печатной формы в табличный документ ...

УправлениеПечатью.ЗадатьОбластьПечатиДокумента(ТабличныйДокумент, НомерСтрокиНачало, ОбъектыПечати, ВыборкаПоДокументам.Ссылка);

КонецЦикла;

//

Функция ТабличныйДокументСправки(МассивСсылок, ОбъектыПечати)

ТабличныйДокумент = Новый ТабличныйДокумент;

ТабличныйДокумент.КлючПараметровПечати = "ПАРАМЕТРЫ\_ПЕЧАТИ\_СправкаОЗаработкеДляРасчетаПособий";

ТабличныйДокумент.АвтоМасштаб = Истина;

ДанныеДокументов = ЗапросПоОсновнымДанным(МассивСсылок).Выполнить().Выгрузить();

ПервыйДокумент = Истина;

Для Каждого ДанныеДокумента Из ДанныеДокументов Цикл

Если ПервыйДокумент Тогда

ПервыйДокумент = Ложь;

Иначе

ТабличныйДокумент.ВывестиГоризонтальныйРазделительСтраниц();

КонецЕсли;

НачалоТекущегоФрагмента = ТабличныйДокумент.ВысотаТаблицы + 1;

ВывестиШапку(ТабличныйДокумент, СоставМакета.Шапка, ДанныеДокумента, АдресаОрганизаций);

ВывестиЗаработок(ТабличныйДокумент, СоставМакета, СтруктураПоиска, ВыборкаЗаработка, Валюта);

ВывестиПодвал(ТабличныйДокумент, СоставМакета.Подвал, ДанныеДокумента, КадровыеДанныеФизическихЛиц);

// В табличном документе зададим имя области, в которую был

// выведен объект. Нужно для возможности печати покомплектно.

УправлениеПечатью.ЗадатьОбластьПечатиДокумента(ТабличныйДокумент, НачалоТекущегоФрагмента, ОбъектыПечати, ДанныеДокумента.Ссылка);

КонецЦикла;

Возврат ТабличныйДокумент;

КонецФункции

627. [**ВыполнитьКомандуПечати**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+L77+7r7ejy/Oru7ODt5PPv5ffg8uguaHRtIw==). Формирует и выводит на экран печатные формы.

УправлениеПечатьюКлиент.ВыполнитьКомандуПечати("Обработка.ПечатнаяФорма", "СписаниеТоваров", ДокументыНаПечать, ЭтотОбъект);

//

Функция ВыполнитьКомандуПечатиСтатистическойФормыУчетаПеремещенияТоваров(ОписаниеКоманды) Экспорт

ПараметрыПечати = ОбщегоНазначенияБПКлиент.ПолучитьЗаголовокПечатнойФормы(ОписаниеКоманды.ОбъектыПечати);

УправлениеПечатьюКлиент.ВыполнитьКомандуПечати(

"Документ.ЗаявлениеОВвозеТоваров",

"СтатистическаяФормаУчетаПеремещенияТоваров",

ОписаниеКоманды.ОбъектыПечати,

ОписаниеКоманды.Форма,

ПараметрыПечати);

КонецФункции

142. [**ДобавитьОписаниеОбласти**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+Tu4eDi6PL87u/o8eDt6OXu4evg8fLoLmh0bSM=). Добавляет к параметру НаборОбластей новую запись об области.

Функция ОбластиМакетаОфисногоДокумента()

Области = Новый Структура;

УправлениеПечатью.ДобавитьОписаниеОбласти(Области, "ВерхнийКолонтитул", "ВерхнийКолонтитул");

УправлениеПечатью.ДобавитьОписаниеОбласти(Области, "НижнийКолонтитул", "НижнийКолонтитул");

УправлениеПечатью.ДобавитьОписаниеОбласти(Области, "Заголовок", "Общая");

Возврат Области;

КонецФункции

**Варианты отчетов**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6MjU5Omhkb2M=)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQwJUIyJUQwJUIwJUQxJTgwJUQwJUI4JUQwJUIwJUQwJUJEJUQxJTgyJUQxJThCXyVEMCVCRSVEMSU4MiVEMSU4NyVEMCVCNSVEMSU4MiVEMCVCRSVEMCVCMg==)

1948. [**ОписаниеВарианта**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7v6PHg7ejl4uDw6ODt8uAuaHRtIw==). Находит настройки варианта отчета. Используется для настройки размещения. Для использования в ВариантыОтчетовПереопределяемый.НастроитьВариантыОтчетов.

[*Подсистема "Варианты отчетов". Используете ли Вы ее правильно?*](https://infostart.ru/1c/articles/1056845/)

Результат = ВариантыОтчетов.ОписаниеВарианта(Настройки, Отчет, КлючВарианта)

618. [**ОписаниеОтчета**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7v6PHg7ejl7vL35fLgLmh0bSM=). Возвращает настройки указанного отчета. Используется для настройки размещения и общих параметров отчета в ВариантыОтчетовПереопределяемый.НастроитьВариантыОтчетов.

Результат = ВариантыОтчетов.ОписаниеОтчета(Настройки, Отчет)

306. [**НастроитьОтчетВМодулеМенеджера**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+3g8fLw7ujy/O7y9+Xy4uzu5PPr5ezl7eXk5uXw4C5odG0j). Вызывает модуль менеджера отчета для заполнения его настроек. Для вызова из процедуры ВариантыОтчетовПереопределяемый.НастроитьВариантыОтчетов.

ВариантыОтчетов.НастроитьОтчетВМодулеМенеджера(Настройки, ОтчетМетаданные)

142. [**ПодключитьСхему**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/u5Orr/vfo8vzx9eXs8y5odG0j). Устанавливает отчету переданную схему и на основании нее, инициализирует компоновщик настроек.

// В обработчике объекта отчета ПередЗагрузкойНастроекВКомпоновщик компоновщик настроек

// инициализируется на основании схемы из общих макетов:

Если КлючСхемы <> "1" Тогда

КлючСхемы = "1";

Схема = ПолучитьОбщийМакет("МояОбщаяСхемаКомпоновки");

ОтчетыСервер.ПодключитьСхему(ЭтотОбъект, Контекст, Схема, КлючСхемы);

КонецЕсли;

//

Процедура ПередЗагрузкойНастроекВКомпоновщик(Контекст, КлючСхемы,

КлючВарианта, НовыеНастройкиКД,

НовыеПользовательскиеНастройкиКД) Экспорт

Если ТипЗнч(Контекст) = Тип("ФормаКлиентскогоПриложения") Тогда

НастроитьПараметрыОтчетаПоВариантуОтчета(Контекст.НастройкиОтчета, НовыеНастройкиКД, НовыеПользовательскиеНастройкиКД);

ОтчетыСервер.ПодключитьСхему(ЭтотОбъект, Контекст, СхемаКомпоновкиДанных, КлючСхемы);

КонецЕсли;

КонецПроцедуры

**Контактная информация**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6Mjc2Omhkb2M=)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQwJUJBJUQwJUJFJUQwJUJEJUQxJTgyJUQwJUIwJUQwJUJBJUQxJTgyJUQwJUJEJUQwJUIwJUQxJThGXyVEMCVCOCVEMCVCRCVEMSU4NCVEMCVCRSVEMSU4MCVEMCVCQyVEMCVCMCVEMSU4NiVEMCVCOCVEMSU4Rg==)

256. [**ЭтоКонтактнаяИнформацияВXML**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/3y7uru7fLg6vLt4P/o7fTu8Ozg9uj/4nhtbC5odG0j). Возвращает признак того, является ли строка данных контактной информации XML данными.

Результат = УправлениеКонтактнойИнформациейКлиентСервер.ЭтоКонтактнаяИнформацияВXML(Текст)

138. [**ЭтоКонтактнаяИнформацияВJSON**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/3y7uru7fLg6vLt4P/o7fTu8Ozg9uj/4mpzb24uaHRtIw==). Возвращает признак того, является ли строка данных контактной информации JSON данными.

Результат = УправлениеКонтактнойИнформациейКлиентСервер.ЭтоКонтактнаяИнформацияВJSON(Текст)

247. [**СведенияОбАдресе**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Hi5eTl7ej/7uHg5PDl8eUuaHRtIw==). Возвращает сведения об адресе в виде отдельных частей адреса и различных кодов (код региона, ОКТМО и др.).

Результат = РаботаСАдресами.СведенияОбАдресе(Адрес, ДополнительныеПараметры)

234. [**ПредставлениеКонтактнойИнформации**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/w5eTx8uDi6+Xt6OXq7u3y4Ory7e7p6O307vDs4Pbo6C5odG0j). Возвращает представление контактной информации (адреса, телефона, электронной почты и т.п.).

[*Работаем с контактной информацией в конфигурациях на БСП*](https://infostart.ru/1c/articles/1260421/)

Результат = УправлениеКонтактнойИнформацией.ПредставлениеКонтактнойИнформации(КонтактнаяИнформация, ВидКонтактнойИнформации)

209. [**КонтактнаяИнформацияОбъекта**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+ru7fLg6vLt4P/o7fTu8Ozg9uj/7uH65ery4C5odG0j). Возвращает таблицу, содержащую контактную информацию объекта.

Результат = УправлениеКонтактнойИнформацией.КонтактнаяИнформацияОбъекта(СсылкаИлиОбъект,

ВидИлиТипКонтактнойИнформации,

Дата,

ТолькоПредставление)

//

Процедура ЗаполнитьДанныеОрганизации()

ТелефоныОрганизации = УправлениеКонтактнойИнформацией.КонтактнаяИнформацияОбъекта(

Организация,

Справочники.ВидыКонтактнойИнформации.ТелефонОрганизации,

?(ЗначениеЗаполнено(Дата), Дата, ТекущаяДатаСеанса()),

Ложь);

Если ТелефоныОрганизации.Количество() > 0 Тогда

РеквизитыДокумента.ТелефонУполномоченногоПредставителя = ТелефоныОрганизации[0].Значение;

Иначе

РеквизитыДокумента.ТелефонУполномоченногоПредставителя = "";

КонецЕсли;

КонецПроцедуры

188. [**КонтактнаяИнформацияВJSON**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+ru7fLg6vLt4P/o7fTu8Ozg9uj/4mpzb24uaHRtIw==). Преобразует входящие форматы контактной информации во внутренний формат JSON.

Результат = УправлениеКонтактнойИнформацией.КонтактнаяИнформацияВJSON(КонтактнаяИнформация, ОжидаемыйВид)

140. [**КонтактнаяИнформацияПоПредставлению**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+ru7fLg6vLt4P/o7fTu8Ozg9uj/7+7v8OXk8fLg4uvl7ej+Lmh0bSM=). Преобразует представление контактной информации во внутренний формат JSON. Для адресов, введенных в свободной форме, корректное преобразование не гарантируется.

Результат = УправлениеКонтактнойИнформацией.КонтактнаяИнформацияПоПредставлению(Представление, ОжидаемыйВид)

174. [**КонтактнаяИнформацияВXML**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+ru7fLg6vLt4P/o7fTu8Ozg9uj/4nhtbC5odG0j). Преобразует все входящие форматы контактной информации в XML.

Результат = УправлениеКонтактнойИнформацией.КонтактнаяИнформацияВXML(ЗначенияПолей, Представление, ОжидаемыйВид)

119. [**КонтактнаяИнформацияОбъектов**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+ru7fLg6vLt4P/o7fTu8Ozg9uj/7uH65ery7uIuaHRtIw==). Возвращает таблицу, содержащую контактную информацию нескольких объектов.

Результат = УправлениеКонтактнойИнформацией.КонтактнаяИнформацияОбъектов(СсылкиИлиОбъекты, ТипыКонтактнойИнформации, ВидыКонтактнойИнформации, Дата)

181. [**ОткрытьФормуКонтактнойИнформации**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7y6vD78vz07vDs8+ru7fLg6vLt7uno7fTu8Ozg9ujoLmh0bSM=). Открывает подходящую форму контактной информации для редактирования или просмотра.

Результат = УправлениеКонтактнойИнформациейКлиент.ОткрытьФормуКонтактнойИнформации(Параметры, Владелец, Оповещение)

115. [**ПараметрыФормыКонтактнойИнформации**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/g8ODs5fLw+/Tu8Oz76u7t8uDq8u3u6ejt9O7w7OD26OguaHRtIw==). Конструктор для структуры параметров открытия формы контактной информации. Состав полей может быть расширен в общем модуле РаботаСАдресамиКлиент свойствами с национальной спецификой.

Результат = УправлениеКонтактнойИнформациейКлиент.ПараметрыФормыКонтактнойИнформации(ВидКонтактнойИнформации, Значение, Представление, Комментарий, ТипКонтактнойИнформации)

**Валюты**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6MjU4Omhkb2M=)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQwJUIyJUQwJUIwJUQwJUJCJUQxJThFJUQxJTgyJUQxJThC)

711. [**ПолучитьКурсВалюты**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/u6/P36PL86vPw8eLg6/7y+y5odG0j). Возвращает курс валюты на дату.

[*Загрузка курсов валют на клиенте*](https://infostart.ru/public/1164863)

Результат = РаботаСКурсамиВалют.ПолучитьКурсВалюты(Валюта, ДатаКурса)

232. [**ПересчитатьПоКурсу**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/l8OXx9+jy4PL87+7q8/Dx8y5odG0j). Пересчитывает сумму из текущей валюты в новую валюту по параметрам их курсов.

Результат = РаботаСКурсамиВалютКлиентСервер.ПересчитатьПоКурсу(Сумма, ПараметрыТекущегоКурса, ПараметрыНовогоКурса)

//

Функция ПересчитатьВВалюту(Сумма, ИсходнаяВалюта, НоваяВалюта, Дата) Экспорт

Возврат РаботаСКурсамиВалютКлиентСервер.ПересчитатьПоКурсу(Сумма,

ПолучитьКурсВалюты(ИсходнаяВалюта, Дата),

ПолучитьКурсВалюты(НоваяВалюта, Дата));

КонецФункции

163. [**СформироватьСуммуПрописью**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/H07vDs6PDu4uDy/PHz7Ozz7/Du7+jx/P4uaHRtIw==). Формирует представление суммы прописью в указанной валюте.

Результат = РаботаСКурсамиВалют.СформироватьСуммуПрописью(СуммаЧислом, Валюта, БезДробнойЧасти, КодЯзыка)

55. [**ПересчитатьВВалюту**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/l8OXx9+jy4PL84uLg6/7y8y5odG0j). Пересчитывает сумму из одной валюты в другую.

Результат = РаботаСКурсамиВалют.ПересчитатьВВалюту(Сумма, ИсходнаяВалюта, НоваяВалюта, Дата)

//

СуммаВал = РаботаСКурсамиВалют.ПересчитатьВВалюту(ДанныеИБ.СуммаДокумента, ДанныеИБ.ВалютаДокумента, ВалютаКонвертации, ДанныеИБ.Дата);

20. [**ОписаниеТипаДенежногоПоля**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7v6PHg7ejl8ujv4OTl7eXm7e7j7u/u6/8uaHRtIw==). Предназначена для использования в конструкторе типа Число для денежных полей.

Результат = РаботаСКурсамиВалют.ОписаниеТипаДенежногоПоля(ДопустимыйЗнакПоля)

//

ДанныеВедомостейДляОплаты = Новый ТаблицаЗначений;

ДенежнаяСуммаНеотрицательная = РаботаСКурсамиВалют.ОписаниеТипаДенежногоПоля(ДопустимыйЗнак.Неотрицательный);

ДанныеВедомостейДляОплаты.Колонки.Добавить("СуммаКВыплате", ДенежнаяСуммаНеотрицательная);

10. [**ДобавитьВалютыПоКоду**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+Tu4eDi6PL84uDr/vL77+7q7uTzLmh0bSM=). Добавляет в справочник валют валюты из классификатора.

Результат = РаботаСКурсамиВалют.ДобавитьВалютыПоКоду(Коды)

// Создаем "Рубли".

Коды = Новый Массив;

Коды.Добавить("643");

РаботаСКурсамиВалют.ДобавитьВалютыПоКоду(Коды);

**Префиксация объектов**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6Mjk1Omhkb2M=)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQwJUJGJUQxJTgwJUQwJUI1JUQxJTg0JUQwJUI4JUQwJUJBJUQxJTgxJUQwJUIwJUQxJTg2JUQwJUI4JUQxJThGXyVEMCVCRSVEMCVCMSVEMSU4QSVEMCVCNSVEMCVCQSVEMSU4MiVEMCVCRSVEMCVCMg==)

1007. [**НомерНаПечать**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+3u7OXw7eDv5ffg8vwuaHRtIw==). Получает номер документа для вывода на печать; из номера удаляются префиксы и лидирующие нули.

Результат = ПрефиксацияОбъектовКлиентСервер.НомерНаПечать(НомерОбъекта, УдалитьПрефиксИнформационнойБазы, УдалитьПользовательскийПрефикс)

//

НомерДокумента = ПрефиксацияОбъектовКлиентСервер.НомерНаПечать(Реквизиты.Номер, Истина, Ложь);

24. [**УдалитьЛидирующиеНулиИзНомераОбъекта**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Pk4Ovo8vzr6OTo8PP++ejl7fPr6Ojn7e7s5fDg7uH65ery4C5odG0j). Удаляет лидирующие нули из номера объекта.

Результат = ПрефиксацияОбъектовКлиентСервер.УдалитьЛидирующиеНулиИзНомераОбъекта(НомерОбъекта)

**Склонение представлений объектов**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6MzA1Omhkb2M=)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQxJTgxJUQwJUJBJUQwJUJCJUQwJUJFJUQwJUJEJUQwJUI1JUQwJUJEJUQwJUI4JUQwJUI1XyVEMCVCRiVEMSU4MCVEMCVCNSVEMCVCNCVEMSU4MSVEMSU4MiVEMCVCMCVEMCVCMiVEMCVCQiVEMCVCNSVEMCVCRCVEMCVCOCVEMCVCOV8lRDAlQkUlRDAlQjElRDElOEElRDAlQjUlRDAlQkElRDElODIlRDAlQkUlRDAlQjI=)

51. [**ПросклонятьПредставление**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/w7vHq6+7t//L87/Dl5PHy4OLr5e3o5S5odG0j). Склоняет переданную фразу по всем падежам.

СклонениеПредставленийОбъектовКлиент.ПросклонятьПредставление(Форма, Представление, ПараметрыСклонения, ПоказыватьСообщения)

//

ДолжностьРуководителя = СклонениеПредставленийОбъектов.ПросклонятьПредставление(Строка(Выборка.ДолжностьРуководителя), 2);

//

&НаКлиенте

Процедура ФИОПриИзменении(Элемент)

ПараметрыСклонения = СклонениеПредставленийОбъектовКлиентСервер.ПараметрыСклонения();

ПараметрыСклонения.ЭтоФИО = Истина;

ПараметрыСклонения.Пол = ?(

ЗначениеЗаполнено(ФизическоеЛицо.Пол),

?(ФизическоеЛицо.Пол = ПредопределенноеЗначение("Перечисление.ПолФизическогоЛица.Мужской"), 1, 2),

Неопределено);

СклонениеПредставленийОбъектовКлиент.ПросклонятьПредставление(ЭтотОбъект, ФизическоеЛицо.ФИО, ПараметрыСклонения);

КонецПроцедуры

51. [**ПараметрыСклонения**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/g8ODs5fLw+/Hq6+7t5e3o/y5odG0j). Конструктор параметров для методов склонения.

Результат = СклонениеПредставленийОбъектовКлиентСервер.ПараметрыСклонения()

//

&НаКлиенте

Процедура НачатьСклонение(ПоказыватьСообщения)

ЗаполнитьСклонениеПоУмолчанию();

ОповещениеОЗавершении = Новый ОписаниеОповещения("ЗавершитьСклонение", ЭтотОбъект);

ПараметрыСклонения = СклонениеПредставленийОбъектовКлиентСервер.ПараметрыСклонения();

ПараметрыСклонения.ЭтоФИО = ЭтоФИО;

ПараметрыСклонения.Пол = Пол;

СклонениеПредставленийОбъектовКлиент.НачатьСклонение(ЭтотОбъект, Представление, ПараметрыСклонения, ПоказыватьСообщения, ОповещениеОЗавершении);

КонецПроцедуры

34. [**ПросклонятьФИО**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/w7vHq6+7t//L89OjuLmh0bSM=). Определяет форму ФИО в заданном падеже.

Результат = СклонениеПредставленийОбъектов.ПросклонятьФИО(ФИО, Падеж, Объект, Пол)

Результат = СклонениеПредставленийОбъектов.ПросклонятьФИО(

СведенияОКонтрагенте.ПолноеНаименование,

Падеж,

СведенияОДоговоре.Владелец,

РуководительКонтрагентаПол);

**Генерация штрихкода**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NjAxMzpoZG9j)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQwJUIzJUQwJUI1JUQwJUJEJUQwJUI1JUQxJTgwJUQwJUIwJUQxJTg2JUQwJUI4JUQxJThGXyVEMSU4OCVEMSU4MiVEMSU4MCVEMCVCOCVEMSU4NSVEMCVCQSVEMCVCRSVEMCVCNCVEMCVCMA==)

8. [**ПараметрыГенерацииШтрихкода**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/g8ODs5fLw++Pl7eXw4Pbo6Pjy8Oj16u7k4C5odG0j). Пустая структура для заполнения параметра "ПараметрыШтрихкода" используемого для получения изображения штрих кода.

Результат = ГенерацияШтрихкода.ПараметрыГенерацииШтрихкода()

//

Функция ДанныеQRКода(QRСтрока, УровеньКоррекции, Размер) Экспорт

ПараметрыШтрихкода = ГенерацияШтрихкода.ПараметрыГенерацииШтрихкода();

ПараметрыШтрихкода.Ширина = Размер;

ПараметрыШтрихкода.Высота = Размер;

ПараметрыШтрихкода.Штрихкод = QRСтрока;

ПараметрыШтрихкода.УровеньКоррекцииQR = УровеньКоррекции;

ПараметрыШтрихкода.ТипКода = 16; // QR

ПараметрыШтрихкода.УбратьЛишнийФон = Истина;

Попытка

РезультатФормированияШтрихкода = ИзображениеШтрихкода(ПараметрыШтрихкода);

ДвоичныеДанныеКартинки = РезультатФормированияШтрихкода.ДвоичныеДанные;

Исключение

ТекстОшибки = НСтр("ru = 'Ошибка формирование QR-кода'");

ЗаписьЖурналаРегистрации(ТекстОшибки, УровеньЖурналаРегистрации.Ошибка, , ,

ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));

КонецПопытки;

Возврат ДвоичныеДанныеКартинки;

КонецФункции

36. [**ИзображениеШтрихкода**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+jn7uHw4Obl7ejl+PLw6PXq7uTgLmh0bSM=). Формирование изображения штрихкода.

[*Генерация штрихкодов с помощью БСП для программистов*](https://infostart.ru/1c/articles/1356920/)

Результат = ГенерацияШтрихкода.ИзображениеШтрихкода(ПараметрыШтрихкода)

8. [**ДанныеQRКода**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+Tg7e375XFy6u7k4C5odG0j). Возвращает двоичные данные для формирования QR-кода.

[*Реализация печати QR кодов*](https://infostart.ru/1c/articles/1136082/)

QRСтрока = УправлениеПечатью.ФорматнаяСтрокаУФЭБС(РеквизитыПлатежа);

ТекстОшибки = "";

ДанныеQRКода = УправлениеПечатью.ДанныеQRКода(QRСтрока, 0, 190, ТекстОшибки);

Если Не ПустаяСтрока(ТекстОшибки)

ОбщегоНазначения.СообщитьПользователю(ТекстОшибки);

КонецЕсли;

КартинкаQRКода = Новый Картинка(ДанныеQRКода);

ОбластьМакета.Рисунки.QRКод.Картинка = КартинкаQRКода;

//

Процедура ВывестиQRКод(ДанныеПечати, ОбластьМакета)

QRСтрока = ИнтеграцияВЕТИСКлиентСервер.ПутьКСерверуСИнформациейПоВСД() + ДанныеПечати.Идентификатор;

Если Не ПустаяСтрока(QRСтрока) Тогда

ДанныеQRКода = УправлениеПечатью.ДанныеQRКода(QRСтрока, 0, 190);

Если ТипЗнч(ДанныеQRКода) = Тип("ДвоичныеДанные") Тогда

КартинкаQRКода = Новый Картинка(ДанныеQRКода);

ОбластьМакета.Рисунки.QRКод.Картинка = КартинкаQRКода;

Иначе

Шаблон = Нстр("ru = 'Не удалось сформировать QR-код для документа %1.

|Технические подробности см. в журнале регистрации.'");

ТекстСообщения = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(Шаблон, ДанныеПечати.Ссылка);

ОбщегоНазначенияКлиентСервер.СообщитьПользователю(ТекстСообщения);

КонецЕсли;

КонецЕсли;

КонецПроцедуры

//

ДанныеQRКода = ГенерацияШтрихкодаВызовСервера.ДанныеQRКода(QRСтрока, 0, 190);

**Работа с файлами**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6MzAwOmhkb2M=)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQxJTgwJUQwJUIwJUQwJUIxJUQwJUJFJUQxJTgyJUQwJUIwXyVEMSU4MV8lRDElODQlRDAlQjAlRDAlQjklRDAlQkIlRDAlQjAlRDAlQkMlRDAlQjg=)

264. [**ОткрытьФайл**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7y6vD78vz04OnrXzAuaHRtIw==). Открывает файл для просмотра или редактирования.

РаботаСФайламиКлиент.ОткрытьФайл(ДанныеФайла, ДляРедактирования)

//

&НаКлиенте

Процедура ОткрытьФайл(Команда)

ДанныеФайла = ПолучитьДанныеФайлаНаСервере(Объект.Ссылка, УникальныйИдентификатор);

Если ДанныеФайла <> Неопределено Тогда

РаботаСФайламиКлиент.ОткрытьФайл(ДанныеФайла, Ложь);

КонецЕсли;

КонецПроцедуры

91. [**ОбновитьФайл**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7h7e7i6PL89ODp6y5odG0j). Обновляет свойства файла без учета версий: двоичные данные, текст, дату изменения, а также другие необязательные свойства. Использовать только для файлов, которые не хранят версии.

РаботаСФайлами.ОбновитьФайл(ПрисоединенныйФайл, ИнформацияОФайле)

//

Процедура ОбновитьДанныеЭД(Знач СообщениеОбмена, Знач ДвоичныеДанныеЭД) Экспорт

ПрисоединенныйФайл = ОбменСБанкамиСлужебный.ПрисоединенныйФайл(СообщениеОбмена);

ИнформацияОФайле = Новый Структура;

ИнформацияОФайле.Вставить("АдресФайлаВоВременномХранилище", ПоместитьВоВременноеХранилище(ДвоичныеДанныеЭД));

ИнформацияОФайле.Вставить("АдресВременногоХранилищаТекста", "");

РаботаСФайлами.ОбновитьФайл(ПрисоединенныйФайл, ИнформацияОФайле);

КонецПроцедуры

90. [**СохранитьФайлКак**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Hu9fDg7ejy/PTg6evq4OouaHRtIw==). Открывает диалог сохранения файл, где пользователь может определить путь и имя для сохранения файла.

РаботаСФайламиКлиент.СохранитьФайлКак(ДанныеФайла, ОбработчикЗавершения)

//

&НаКлиенте

Процедура ПолучитьФайлПродолжить(Результат, ДанныеФайла) Экспорт

Если Результат = "Открыть" Тогда

РаботаСФайламиКлиент.ОткрытьФайл(ДанныеФайла);

ИначеЕсли Результат = "Сохранить" Тогда

РаботаСФайламиКлиент.СохранитьФайлКак(ДанныеФайла);

КонецЕсли;

КонецПроцедуры

40. [**ДобавитьФайл**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+Tu4eDi6PL89ODp6y5odG0j). Создает объект в справочнике для хранения файла и заполняет его реквизиты переданными свойствами.

Результат = РаботаСФайлами.ДобавитьФайл(ПараметрыФайла,

АдресФайлаВоВременномХранилище,

АдресВременногоХранилищаТекста,

Описание,

НоваяСсылкаНаФайл)

//

ПараметрыФайла = Новый Структура();

ПараметрыФайла.Вставить("Автор", Пользователи.АвторизованныйПользователь());

ПараметрыФайла.Вставить("ВладелецФайлов", Реквизиты.Документ);

ПараметрыФайла.Вставить("ИмяБезРасширения", Строка(Новый УникальныйИдентификатор));

ПараметрыФайла.Вставить("РасширениеБезТочки", "xml");

ПараметрыФайла.Вставить("ВремяИзмененияУниверсальное");

ПрисоединенныйФайл = РаботаСФайлами.ДобавитьФайл(

ПараметрыФайла,

АдресФайлаВоВременномХранилище,,,

Справочники.ГИСМПрисоединенныеФайлы.ПолучитьСсылку());

28. [**ДобавитьФайлы**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+Tu4eDi6PL89ODp6/suaHRtIw==). Открывает диалог выбора файлов для помещения в программу одного или нескольких файлов.

РаботаСФайламиКлиент.ДобавитьФайлы(ВладелецФайла, ИдентификаторФормы, Фильтр, ГруппаФайлов, ОбработчикРезультата)

//

&НаКлиенте

Процедура ДобавитьФайл()

ТекущиеДанные = Элементы.Список.ТекущиеДанные;

ГруппаФайлов = Неопределено;

Если ТекущиеДанные <> Неопределено И ТекущиеДанные.ЭтоГруппа И ТекущиеДанные.ВладелецФайла = Параметры.ВладелецФайла Тогда

ГруппаФайлов = ТекущиеДанные.Ссылка;

КонецЕсли;

Если ЭтоВладелецЭлементовСправочникаФайлы Тогда

РаботаСФайламиСлужебныйКлиент.ДобавитьФайлИзФайловойСистемы(Параметры.ВладелецФайла, ЭтотОбъект);

Иначе

// РаботаСФайламиКлиент.ДобавитьФайлы

РаботаСФайламиКлиент.ДобавитьФайлы(Параметры.ВладелецФайла, УникальныйИдентификатор, , ГруппаФайлов);

КонецЕсли;

КонецПроцедуры

240. [**ДвоичныеДанныеФайла**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+Ti7uj37fvl5ODt7fvl9ODp6+AuaHRtIw==). Возвращает двоичные данные файла.

//Сохранение данных файла на сервере:

ДанныеФайла = РаботаСФайлами.ДвоичныеДанныеФайла(Файл, Ложь);

Если ДанныеФайла <> Неопределено Тогда

ДанныеФайла.Записать(ПутьКФайлу);

КонецЕсли;

//

Рисунок.Картинка = Новый Картинка(РаботаСФайлами.ДвоичныеДанныеФайла(Выборка.ПрисоединенныйФайл));

//

АдресФайлаВыгрузки = ПоместитьВоВременноеХранилище(РаботаСФайлами.ДвоичныеДанныеФайла(Доверенность),

Новый УникальныйИдентификатор);

108. [**ЗаполнитьПрисоединенныеФайлыКОбъекту**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+fg7+7r7ejy/O/w6PHu5eTo7eXt7fvl9ODp6/vq7uH65ery8y5odG0j). Находит все присоединенные к объекту файлы и добавляет ссылки на них в свойство Файлы.

РаботаСФайлами.ЗаполнитьПрисоединенныеФайлыКОбъекту(ВладелецФайла, Файлы)

83. [**ПараметрыДанныхФайла**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/g8ODs5fLw++Tg7e379fTg6evgLmh0bSM=). Инициализирует структуру параметров для получения данных файла. См. РаботаСФайлами.ДанныеФайла.

Результат = РаботаСФайламиКлиентСервер.ПараметрыДанныхФайла()

77. [**ОткрытьФормуФайла**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7y6vD78vz07vDs8/Tg6evgLmh0bSM=). Открывает форму файла. Может использоваться как обработчик открытия файла.

РаботаСФайламиКлиент.ОткрытьФормуФайла(ПрисоединенныйФайл, СтандартнаяОбработка, ДополнительныеПараметры, ОписаниеОповещенияОЗакрытии)

30. [**ОткрытьКаталогФайла**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7y6vD78vzq4PLg6+7j9ODp6+AuaHRtIw==). Открывает в стандартной программе просмотра (проводнике) каталог на компьютере, в котором размещен указанный файл.

РаботаСФайламиКлиент.ОткрытьКаталогФайла(ДанныеФайла)

22. [**ОткрытьФормуВыбораФайлов**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7y6vD78vz07vDs8+L74e7w4PTg6evu4i5odG0j). Открывает форму выбора файлов. Используется в обработчике выбора для переопределения стандартного поведения.

РаботаСФайламиКлиент.ОткрытьФормуВыбораФайлов(ВладелецФайлов, ЭлементФормы, СтандартнаяОбработка, ОписаниеОповещенияОВыборе)

36. [**ПараметрыДобавленияФайла**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/g8ODs5fLw++Tu4eDi6+Xt6P/04Onr4C5odG0j). Инициализирует структуру параметров для добавления файла. Для использования в РаботаСФайлами.ДобавитьВФайл.

Результат = РаботаСФайлами.ПараметрыДобавленияФайла(ДополнительныеРеквизиты)

33. [**НоваяСсылкаНаФайл**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+3u4uD/8fH76+rg7eD04OnrLmh0bSM=). Возвращает новую ссылку на файл для указанного владельца файла. В частности, ссылка используется при добавлении файла в функции ДобавитьФайл.

Результат = РаботаСФайлами.НоваяСсылкаНаФайл(ВладелецФайлов, ИмяСправочника)

**Получение файлов из Интернета**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6MjkzOmhkb2M=)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQwJUJGJUQwJUJFJUQwJUJCJUQxJTgzJUQxJTg3JUQwJUI1JUQwJUJEJUQwJUI4JUQwJUI1XyVEMSU4NCVEMCVCMCVEMCVCOSVEMCVCQiVEMCVCRSVEMCVCMl8lRDAlQjglRDAlQjdfJUQwJUI4JUQwJUJEJUQxJTgyJUQwJUI1JUQxJTgwJUQwJUJEJUQwJUI1JUQxJTgyJUQwJUIw)

52. [**ПараметрыПолученияФайла**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/g8ODs5fLw++/u6/P35e3o//Tg6evgLmh0bSM=). Возвращает структуру параметров для получения файла из Интернета.

Результат = ПолучениеФайловИзИнтернетаКлиентСервер.ПараметрыПолученияФайла()

//

Процедура ПолучитьИнформациюОВнешнейКомпоненте(Параметры, Адрес) Экспорт

ВремФайл = ПолучитьИмяВременногоФайла("xml");

ПараметрыПолучения = ПолучениеФайловИзИнтернетаКлиентСервер.ПараметрыПолученияФайла();

ПараметрыПолучения.ПутьДляСохранения = ВремФайл;

ПараметрыПолучения.Таймаут = 30;

РезультатИнфоФайл = ПолучениеФайловИзИнтернета.СкачатьФайлНаСервере(Параметры.URLИнфоФайла, ПараметрыПолучения);

Если РезультатИнфоФайл.Статус Тогда

ПараметрыВК = ПараметрыВК(ВремФайл);

ФайловаяСистема.УдалитьВременныйФайл(ВремФайл);

ПоместитьВоВременноеХранилище(ПараметрыВК, Адрес);

КонецЕсли;

КонецПроцедуры

59. [**СкачатьФайлВоВременноеХранилище**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Hq4Pfg8vz04Onr4u7i8OXs5e3t7uX18ODt6Ovo+eUuaHRtIw==). Получает файл из Интернета по протоколу http(s), либо ftp и сохраняет его во временное хранилище.

Результат = ПолучениеФайловИзИнтернета.СкачатьФайлВоВременноеХранилище(URL, ПараметрыПолучения, ЗаписыватьОшибку)

//

Процедура ЗагрузитьСписокБанковССайта() Экспорт

АдресСервера = "https://directbank.1c.ru/downloads/bankslist.mxl";

ПараметрыПолучения = ПолучениеФайловИзИнтернетаКлиентСервер.ПараметрыПолученияФайла();

ПараметрыПолучения.Таймаут = 60;

Результат = ПолучениеФайловИзИнтернета.СкачатьФайлВоВременноеХранилище(АдресСервера, ПараметрыПолучения);

Если Результат.Статус Тогда

Данные = ПолучитьИзВременногоХранилища(Результат.Путь);

УдалитьИзВременногоХранилища(Результат.Путь);

ВремФайл = ПолучитьИмяВременногоФайла("mxl");

Данные.Записать(ВремФайл);

КонецЕсли;

КонецПроцедуры

25. [**СкачатьФайлНаСервере**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Hq4Pfg8vz04Onr7eDx5fDi5fDlLmh0bSM=). Получает файл из Интернета по протоколу http(s), либо ftp и сохраняет его по указанному пути на сервере.

Результат = ПолучениеФайловИзИнтернета.СкачатьФайлНаСервере(URL, ПараметрыПолучения, ЗаписыватьОшибку)

//

РезультатПолученияФайла = ПолучениеФайловИзИнтернета.СкачатьФайлНаСервере("https://reputils.1c.ru/static/online\_stats.json");

8. [**СкачатьФайлНаКлиенте**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Hq4Pfg8vz04Onr7eDq6+jl7fLlLmh0bSM=). Получает файл из Интернета по протоколу http(s), либо ftp и сохраняет его по указанному пути на клиенте. Недоступно при работе в веб-клиенте. При работе в веб-клиенте необходимо пользоваться аналогичными серверными процедурами для скачивания файлов.

Результат = ПолучениеФайловИзИнтернетаКлиент.СкачатьФайлНаКлиенте(URL, ПараметрыПолучения, ЗаписыватьОшибку)

//

ПараметрыПолучения = ПолучениеФайловИзИнтернетаКлиентСервер.ПараметрыПолученияФайла();

ПараметрыПолучения.Вставить("ПутьДляСохранения", ЭтотОбъект.ИмяФайлаУстановки);

ПараметрыПолучения.Вставить("Таймаут", ЭтотОбъект.Таймаут);

РезультатЗагрузки = ПолучениеФайловИзИнтернетаКлиент.СкачатьФайлНаКлиенте(

ЭтотОбъект.СсылкаНаСкачивание, // URL.

ПараметрыПолучения, // ПараметрыПолучения.

Истина); // ЗаписыватьОшибку.

0. [**ДиагностикаСоединения**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+To4OPt7vHy6Org8e7l5Ojt5e3o/y5odG0j). Запускает диагностику сетевого ресурса.

// Диагностика веб-сервиса адресного классификатора.

Результат = ОбщегоНазначенияКлиентСервер.ДиагностикаСоединения("https://api.orgaddress.1c.com/orgaddress/v1?wsdl");

ОписаниеОшибки = Результат.ОписаниеОшибки;

ЖурналДиагностики = Результат.ЖурналДиагностики;

//

Попытка

Ответ = Соединение.ОтправитьДляОбработки(ЗапросКСервису);

Исключение

ЗарегистрироватьОшибкуСервиса(ИнформацияОбОшибке(), ПоказыватьСообщения);

РезультатДиагностики = ПолучениеФайловИзИнтернета.ДиагностикаСоединения(Соединение.Сервер);

ВызватьИсключение СтрШаблон(

НСтр("ru = '%1

|

|Результат диагностики:

|%2'"),

КраткоеПредставлениеОшибки(ИнформацияОбОшибке()),

РезультатДиагностики.ОписаниеОшибки);

КонецПопытки;

**Даты запрета изменения**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6MjY2Omhkb2M=)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQwJUI0JUQwJUIwJUQxJTgyJUQxJThCXyVEMCVCNyVEMCVCMCVEMCVCRiVEMSU4MCVEMCVCNSVEMSU4MiVEMCVCMF8lRDAlQjglRDAlQjclRDAlQkMlRDAlQjUlRDAlQkQlRDAlQjUlRDAlQkQlRDAlQjglRDElOEY=)

1375. [**ДобавитьСтроку**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+Tu4eDi6PL88fLw7urzLmh0bSM=). Добавляет строку описания источника данных для проверки запрета изменения. Используется в процедуре ЗаполнитьИсточникиДанныхДляПроверкиЗапретаИзменения общего модуля ДатыЗапретаИзмененияПереопределяемый.

ДатыЗапретаИзменения.ДобавитьСтроку(Данные, Таблица, ПолеДаты, Раздел, ПолеОбъекта)

931. [**ОбъектПриЧтенииНаСервере**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7h+uXq8u/w6Pfy5e3o6O3g8eXw4uXw5S5odG0j). Обработчик события формы ПриЧтенииНаСервере, который встраивается в формы элементов справочников, документов, записей регистров и др., чтобы заблокировать форму, если изменение запрещено.

Результат = ДатыЗапретаИзменения.ОбъектПриЧтенииНаСервере(Форма, ТекущийОбъект)

//

&НаСервере

Процедура ПриЧтенииНаСервере(ТекущийОбъект)

// Обработчик механизма "ДатыЗапретаИзменения"

ДатыЗапретаИзменения.ОбъектПриЧтенииНаСервере(ЭтаФорма, ТекущийОбъект);

КонецПроцедуры

50. [**ШаблонДанныхДляПроверки**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/jg4evu7eTg7e379eTr/+/w7uLl8OroLmh0bSM=). Возвращает новую таблицу значений с колонками Дата, Раздел и Объект для заполнения и последующей передачи в функцию ДатыЗапретаИзменения.НайденЗапретИзмененияДанных.

Результат = ДатыЗапретаИзменения.ШаблонДанныхДляПроверки()

41. [**ИзменениеЗапрещено**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+jn7OXt5e3o5efg7/Dl+eXt7i5odG0j). Проверяет, запрещено ли изменение данных при интерактивном редактировании пользователем или при программной загрузке данных из узла плана обмена УзелПроверкиЗапретаЗагрузки.

Результат = ДатыЗапретаИзменения.ИзменениеЗапрещено(ДанныеИлиПолноеИмя, ИдентификаторДанных, ОписаниеОшибки, УзелПроверкиЗапретаЗагрузки)

30. [**НайденЗапретИзмененияДанных**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+3g6eTl7efg7/Dl8ujn7OXt5e3o/+Tg7e379S5odG0j). Найти даты запрета по проверяемым данным для указанного пользователя или узла плана обмена.

Результат = ДатыЗапретаИзменения.НайденЗапретИзмененияДанных(ДанныеДляПроверки, ПараметрыСообщенияОЗапрете, ОписаниеОшибки, УзелПроверкиЗапретаЗагрузки)

10. [**ПараметрыСообщенияОЗапрете**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/g8ODs5fLw+/Hu7uH55e3o/+7n4O/w5fLlLmh0bSM=). Возвращает параметры для формирования сообщение о запрете записи или загрузки данных. Для использования в функции ДатыЗапретаИзменения.НайденЗапретИзмененияДанных.

Результат = ДатыЗапретаИзменения.ПараметрыСообщенияОЗапрете()

5. [**ПроверитьДатуЗапретаИзмененияПередЗаписьюДокумента**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/w7uLl8Ojy/OTg8vPn4O/w5fLg6Ofs5e3l7ej/7+Xw5eTn4O/o8fz+5O7q8+zl7fLgLmh0bSM=). Обработчик подписки на событие ПередЗаписью для проверки запрета изменения.

ДатыЗапретаИзменения.ПроверитьДатуЗапретаИзмененияПередЗаписьюДокумента(Источник, Отказ, РежимЗаписи, РежимПроведения)

0. [**ОтключитьПроверкуДатЗапрета**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7y6uv+9+jy/O/w7uLl8Orz5ODy5+Dv8OXy4C5odG0j). В текущем сеансе отключает и включает проверку дат запрета изменения и загрузки данных. Для использования требуются полные права или привилегированный режим.

//Вариант 1. Запись набора объектов вне транзакции (ТранзакцияАктивна() = Ложь).

ПроверкаДатЗапретаОтключена = ДатыЗапретаИзменения.ПроверкаДатЗапретаОтключена();

ДатыЗапретаИзменения.ОтключитьПроверкуДатЗапрета(Истина);

Попытка

// Запись набора объектов.

// ...

Исключение

ДатыЗапретаИзменения.ОтключитьПроверкуДатЗапрета(ПроверкаДатЗапретаОтключена);

//...

ВызватьИсключение;

КонецПопытки;

ДатыЗапретаИзменения.ОтключитьПроверкуДатЗапрета(ПроверкаДатЗапретаОтключена);

//Вариант 2. Запись набора объектов в транзакции (ТранзакцияАктивна() = Истина).

ПроверкаДатЗапретаОтключена = ДатыЗапретаИзменения.ПроверкаДатЗапретаОтключена();

ДатыЗапретаИзменения.ОтключитьПроверкуДатЗапрета(Истина);

НачатьТранзакцию();

Попытка

БлокировкаДанных.Заблокировать();

// ...

// Запись набора объектов.

// ...

ЗафиксироватьТранзакцию();

Исключение

ОтменитьТранзакцию();

ДатыЗапретаИзменения.ОтключитьПроверкуДатЗапрета(ПроверкаДатЗапретаОтключена);

//...

ВызватьИсключение;

КонецПопытки;

ДатыЗапретаИзменения.ОтключитьПроверкуДатЗапрета(ПроверкаДатЗапретаОтключена);

**Запрет редактирования реквизитов объектов**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6MjcxOmhkb2M=)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQwJUI3JUQwJUIwJUQwJUJGJUQxJTgwJUQwJUI1JUQxJTgyXyVEMSU4MCVEMCVCNSVEMCVCNCVEMCVCMCVEMCVCQSVEMSU4MiVEMCVCOCVEMSU4MCVEMCVCRSVEMCVCMiVEMCVCMCVEMCVCRCVEMCVCOCVEMSU4Rl8lRDElODAlRDAlQjUlRDAlQkElRDAlQjIlRDAlQjglRDAlQjclRDAlQjglRDElODIlRDAlQkUlRDAlQjJfJUQwJUJFJUQwJUIxJUQxJThBJUQwJUI1JUQwJUJBJUQxJTgyJUQwJUJFJUQwJUIy)

368. [**ЗаблокироватьРеквизиты**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+fg4evu6ujw7uLg8vzw5eri6Ofo8vsuaHRtIw==). Принимает в качестве параметра форму объекта, к которому подключена подсистема, и запрещает редактирование заданных реквизитов, а также добавляет во "Все действия" команду для разрешения их редактирования.

ЗапретРедактированияРеквизитовОбъектов.ЗаблокироватьРеквизиты(Форма, ГруппаДляКнопкиЗапрета, ЗаголовокКнопкиЗапрета, Объект)

//

&НаСервере

Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

// Подсистема запрета редактирования ключевых реквизитов объектов.

ЗапретРедактированияРеквизитовОбъектов.ЗаблокироватьРеквизиты(ЭтотОбъект);

КонецПроцедуры

&НаСервере

Процедура ПослеЗаписиНаСервере(ТекущийОбъект, ПараметрыЗаписи)

// Обработчик подсистемы запрета редактирования реквизитов объектов.

ЗапретРедактированияРеквизитовОбъектов.ЗаблокироватьРеквизиты(ЭтаФорма);

КонецПроцедуры

82. [**УстановитьДоступностьЭлементовФормы**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Px8uDt7uLo8vzk7vHy8+/t7vHy/P3r5ezl7fLu4vTu8Oz7Lmh0bSM=). Устанавливает доступность элементов формы, связанных с заданными реквизитами, для которых установлено разрешение изменения.

ЗапретРедактированияРеквизитовОбъектовКлиент.УстановитьДоступностьЭлементовФормы(Форма, Реквизиты)

//

&НаКлиенте

Процедура Подключаемый\_РазрешитьРедактированиеРеквизитовОбъекта(Команда)

Если Не Объект.Ссылка.Пустая() Тогда

ОткрытьФорму("Справочник.Кассы.Форма.РазблокированиеРеквизитов",,,,,,

Новый ОписаниеОповещения("Подключаемый\_РазрешитьРедактированиеРеквизитовОбъектаЗавершение", ЭтотОбъект),

РежимОткрытияОкнаФормы.БлокироватьОкноВладельца);

КонецЕсли;

КонецПроцедуры

&НаКлиенте

Процедура Подключаемый\_РазрешитьРедактированиеРеквизитовОбъектаЗавершение(Результат, ДополнительныеПараметры) Экспорт

Если ТипЗнч(Результат) = Тип("Массив") И Результат.Количество() > 0 Тогда

ЗапретРедактированияРеквизитовОбъектовКлиент.УстановитьДоступностьЭлементовФормы(ЭтаФорма, Результат);

КонецЕсли;

КонецПроцедуры

42. [**РазрешитьРедактированиеРеквизитовОбъекта**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Dg5/Dl+Ojy/PDl5ODq8ujw7uLg7ejl8OXq4ujn6PLu4u7h+uXq8uAuaHRtIw==). Разрешает редактирование заблокированных элементов формы, связанных с заданными реквизитами.

ЗапретРедактированияРеквизитовОбъектовКлиент.РазрешитьРедактированиеРеквизитовОбъекта(Форма, ОбработкаПродолжения)

//

&НаКлиенте

Процедура Подключаемый\_РазрешитьРедактированиеРеквизитовОбъекта(Команда)

ЗапретРедактированияРеквизитовОбъектовКлиент.РазрешитьРедактированиеРеквизитовОбъекта(ЭтотОбъект);

КонецПроцедуры

26. [**Реквизиты**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Dl6uLo5+jy+y5odG0j). Возвращает массив имен реквизитов, заданных в свойстве формы ПараметрыЗапретаРедактированияРеквизитов на основе имен реквизитов, указанных в модуле менеджера объекта, исключая реквизиты, у которых ПравоРедактирования = Ложь.

Результат = ЗапретРедактированияРеквизитовОбъектовКлиент.Реквизиты(Форма, ТолькоЗаблокированные, ТолькоВидимые)

//

&НаКлиенте

Процедура Подключаемый\_РазрешитьРедактированиеРеквизитовОбъекта(Команда)

Оповещение = Новый ОписаниеОповещения("РазрешитьРедактированиеРеквизитовОбъектаЗавершение", ЭтотОбъект);

ОбщегоНазначенияУТКлиент.РазрешитьРедактированиеРеквизитовОбъекта(ЭтаФорма,,Оповещение);

КонецПроцедуры

&НаКлиенте

Процедура РазрешитьРедактированиеРеквизитовОбъектаЗавершение(Результат, ДополнительныеПараметры) Экспорт

Если Результат = Истина Тогда

Реквизиты = ЗапретРедактированияРеквизитовОбъектовКлиент.Реквизиты(ЭтаФорма, , Ложь);

ЗапретРедактированияРеквизитовОбъектовКлиент.УстановитьРазрешенностьРедактированияРеквизитов(ЭтаФорма, Реквизиты);

ЗапретРедактированияРеквизитовОбъектовКлиент.УстановитьДоступностьЭлементовФормы(ЭтаФорма, Реквизиты);

КонецЕсли;

КонецПроцедуры

14. [**УстановитьРазрешенностьРедактированияРеквизитов**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Px8uDt7uLo8vzw4Ofw5fjl7e3u8fL88OXk4Ory6PDu4uDt6P/w5eri6Ofo8u7iLmh0bSM=). Устанавливает разрешенность редактирования для тех реквизитов, описание которых подготовлено в форме. Используется, когда доступность элементов формы изменяется самостоятельно, без использования функции УстановитьДоступностьЭлементовФормы.

ЗапретРедактированияРеквизитовОбъектовКлиент.УстановитьРазрешенностьРедактированияРеквизитов(Форма, Реквизиты, РедактированиеРазрешено, ПравоРедактирования)

//

ЗаблокированныеРеквизиты = ЗапретРедактированияРеквизитовОбъектовКлиент.Реквизиты(Форма);

ЗапретРедактированияРеквизитовОбъектовКлиент.УстановитьРазрешенностьРедактированияРеквизитов(Форма, ЗаблокированныеРеквизиты);

ЗапретРедактированияРеквизитовОбъектовКлиент.УстановитьДоступностьЭлементовФормы(Форма);

12. [**ПоказатьПредупреждениеВсеВидимыеРеквизитыРазблокированы**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/u6uDn4PL87/Dl5PPv8OXm5OXt6OXi8eXi6OTo7Pvl8OXq4ujn6PL78ODn4evu6ujw7uLg7fsuaHRtIw==). Выводит предупреждение о том, что все видимые реквизиты разблокированы.

ЗапретРедактированияРеквизитовОбъектовКлиент.ПоказатьПредупреждениеВсеВидимыеРеквизитыРазблокированы(ОбработкаПродолжения)

//

&НаКлиенте

Процедура Подключаемый\_РазрешитьРедактированиеРеквизитовОбъекта(Команда)

ЗаблокированныеРеквизиты = ЗапретРедактированияРеквизитовОбъектовКлиент.Реквизиты(ЭтотОбъект);

Если ЗаблокированныеРеквизиты.Количество() > 0 Тогда

ПараметрыФормы = Новый Структура;

ПараметрыФормы.Вставить("Ссылка", Объект.Ссылка);

ПараметрыФормы.Вставить("ЗаблокированныеРеквизиты", ЗаблокированныеРеквизиты);

ОткрытьФорму(

"Справочник.ОбъектыЭксплуатации.Форма.РазблокированиеРеквизитов",

ПараметрыФормы,

ЭтотОбъект);

Иначе

ЗапретРедактированияРеквизитовОбъектовКлиент.ПоказатьПредупреждениеВсеВидимыеРеквизитыРазблокированы();

КонецЕсли;

КонецПроцедуры

3. [**БлокируемыеРеквизитыОбъекта**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+Hr7uro8PPl7Pvl8OXq4ujn6PL77uH65ery4C5odG0j). Возвращает список реквизитов и табличных частей объекта, по которым установлен запрет редактирования.

Результат = ЗапретРедактированияРеквизитовОбъектов.БлокируемыеРеквизитыОбъекта(ИмяОбъекта)

//

БлокируемыеРеквизиты = Новый Массив;

БлокируемыеРеквизиты = РаботаСНоменклатурой.БлокируемыеРеквизитыОбъекта(ОбъектМетаданных.ПолноеИмя());

1. [**ПроверитьСсылкиНаОбъект**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/w7uLl8Ojy/PHx++vq6O3g7uH65eryLmh0bSM=). Спрашивает у пользователя подтверждение на включение редактирования реквизитов и проверяет, есть ли ссылки на объект в информационной базе.

ЗапретРедактированияРеквизитовОбъектовКлиент.ПроверитьСсылкиНаОбъект(ОбработкаПродолжения, МассивСсылок, СинонимыРеквизитов)

**Дополнительные отчеты и обработки**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6MjY3Omhkb2M=)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQwJUI0JUQwJUJFJUQwJUJGJUQwJUJFJUQwJUJCJUQwJUJEJUQwJUI4JUQxJTgyJUQwJUI1JUQwJUJCJUQxJThDJUQwJUJEJUQxJThCJUQwJUI1XyVEMCVCRSVEMSU4MiVEMSU4NyVEMCVCNSVEMSU4MiVEMSU4Ql8lRDAlQjhfJUQwJUJFJUQwJUIxJUQxJTgwJUQwJUIwJUQwJUIxJUQwJUJFJUQxJTgyJUQwJUJBJUQwJUI4)

0. [**СведенияОВнешнейОбработке**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Hi5eTl7ej/7uLt5fjt5enu4fDg4e7y6uUuaHRtIw==). Формирует шаблон сведений о внешнем отчете или обработке для последующего заполнения.

Результат = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке(ВерсияБСП)

// Фрагмент примера параметров

Функция СведенияОВнешнейОбработке() Экспорт

Инфо = Новый Структура;

Инфо.Вставить("Вид", "СозданиеСвязанныхОбъектов");

Инфо.Вставить("Команды", Новый ТаблицаЗначений);

Инфо.Вставить("БезопасныйРежим", Истина);

Инфо.Вставить("Назначение", Новый Массив);

Инфо.Вставить("Наименование", НСтр("ru = 'Регистрация изменений для обмена данными'"));

Инфо.Вставить("Версия", "1.0");

Инфо.Вставить("ВерсияБСП", "1.2.1.4");

Инфо.Вставить("Информация", НСтр("ru = 'Обработка для управления регистрацией объектов на узлах обмена до формирования выгрузки.'"));

..

30. [**ОбъектВнешнейОбработки**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7h+uXq8uLt5fjt5enu4fDg4e7y6uguaHRtIw==). Создает и возвращает экземпляр внешней обработки (отчета)

Результат = ДополнительныеОтчетыИОбработкиВызовСервера.ОбъектВнешнейОбработки(Ссылка)

//

ВнешняяОбработка = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(ВариантРаспределения, "ВнешняяОбработка");

ВнешняяОбработкаОбъект = ДополнительныеОтчетыИОбработки.ОбъектВнешнейОбработки(ВнешняяОбработка);

ВнешняяОбработкаОбъект.ВыполнитьРаспределение(ТоварыФакт, СерийныеНомераФакт, ТоварыПеремещение, СерийныеНомераПеремещение, НастройкиВарианта, ИдентификаторыВыделенныхСтрок, ФормаРаспределения);

//

ВнешняяОбработка = ДанныеНастройки.ВнешняяОбработка;

ВнешнийОбъект = ДополнительныеОтчетыИОбработки.ОбъектВнешнейОбработки(ВнешняяОбработка);

ВнешнийОбъект.АлгоритмИсполнения(ДанныеНастройки, МассивНайденныхФайлов);

35. [**ПодключитьВнешнююОбработку**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/u5Orr/vfo8vzi7eX47f7+7uHw4OHu8urzLmh0bSM=). Подключает и возвращает имя, под которым подключен внешний отчет или обработка.

// Вызов с сервера

Результат = ДополнительныеОтчетыИОбработки.ПодключитьВнешнююОбработку(Ссылка)

// Вызов с клиента

Результат = ДополнительныеОтчетыИОбработкиВызовСервера.ПодключитьВнешнююОбработку(Ссылка);

//

ИмяОбработки = ДополнительныеОтчетыИОбработкиВызовСервера.ПодключитьВнешнююОбработку(Ссылка);

Если ВыполняемаяКоманда.ЭтоОтчет Тогда

ФормаОбработки = ПолучитьФорму("ВнешнийОтчет."+ ИмяОбработки +".Форма", ПараметрыОбработки, Форма);

Иначе

ФормаОбработки = ПолучитьФорму("ВнешняяОбработка."+ ИмяОбработки +".Форма", ПараметрыОбработки, Форма);

КонецЕсли;

0. [**ВыполнитьКомандуВФоне**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+L77+7r7ejy/Oru7ODt5PPi9O7t5S5odG0j). Выполняет команду ИдентификаторКоманды в фоне с помощью механизма длительных операций. Для использования в формах внешних отчетов и обработок.

&НаКлиенте

Процедура ОбработчикКоманды(Команда)

ПараметрыКоманды = ДополнительныеОтчетыИОбработкиКлиент.ПараметрыВыполненияКомандыВФоне(Параметры.ДополнительнаяОбработкаСсылка);

ПараметрыКоманды.СопровождающийТекст = НСтр("ru = 'Выполняется команда...'");

Обработчик = Новый ОписаниеОповещения("<ИмяЭкспортнойПроцедуры>", ЭтотОбъект);

ДополнительныеОтчетыИОбработкиКлиент.ВыполнитьКомандуВФоне(Команда.Имя, ПараметрыКоманды, Обработчик);

КонецПроцедуры

11. [**ВыполнитьКоманду**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+L77+7r7ejy/Oru7ODt5PMuaHRtIw==). Выполняет команду обработки и возвращает результат ее выполнения.

Результат = ДополнительныеОтчетыИОбработки.ВыполнитьКоманду(ПараметрыКоманды, АдресРезультата)

150. [**ОткрытьФормуКомандДополнительныхОтчетовИОбработок**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7y6vD78vz07vDs8+ru7ODt5OTu7+7r7ejy5ev87fv17vL35fLu4uju4fDg4e7y7uouaHRtIw==). Открывает форму с доступными командами.

ДополнительныеОтчетыИОбработкиКлиент.ОткрытьФормуКомандДополнительныхОтчетовИОбработок(ПараметрКоманды,

ПараметрыВыполненияКоманды,

Вид,

ИмяРаздела)

//

&НаКлиенте

Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)

ДополнительныеОтчетыИОбработкиКлиент.ОткрытьФормуКомандДополнительныхОтчетовИОбработок(

ПараметрКоманды,

ПараметрыВыполненияКоманды,

ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительнаяОбработка(),

"Склад");

КонецПроцедуры

79. [**ВидОбработкиДополнительныйОтчет**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+Lo5O7h8ODh7vLq6OTu7+7r7ejy5ev87fvp7vL35fIuaHRtIw==). Дополнительный отчет, обработка, печатная форома

Результат = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиОтчет()

Результат = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиОбработка()

Результат = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиПечатнаяФорма()

Результат = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительныйОтчет()

Результат = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительнаяОбработка()

//

&НаКлиенте

Процедура ОбработкаКоманды(ПараметрКоманды, ПараметрыВыполненияКоманды)

ДополнительныеОтчетыИОбработкиКлиент.ОткрытьФормуКомандДополнительныхОтчетовИОбработок(

ПараметрКоманды,

ПараметрыВыполненияКоманды,

ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиДополнительнаяОбработка(), // вызов

"ФинансовыйРезультатИКонтроллинг");

КонецПроцедуры

**Работа с почтовыми сообщениями**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6Mjk5Omhkb2M=)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQxJTgwJUQwJUIwJUQwJUIxJUQwJUJFJUQxJTgyJUQwJUIwXyVEMSU4MV8lRDAlQkYlRDAlQkUlRDElODclRDElODIlRDAlQkUlRDAlQjIlRDElOEIlRDAlQkMlRDAlQjhfJUQxJTgxJUQwJUJFJUQwJUJFJUQwJUIxJUQxJTg5JUQwJUI1JUQwJUJEJUQwJUI4JUQxJThGJUQwJUJDJUQwJUI4)

30. [**ДоступныеУчетныеЗаписи**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+Tu8fLz7+375fP35fLt++Xn4O/o8eguaHRtIw==). Получить доступные учетные записи электронной почты.

Результат = РаботаСПочтовымиСообщениями.ДоступныеУчетныеЗаписи(ДляОтправки, ДляПолучения, ВключатьСистемнуюУчетнуюЗапись)

//

ДоступныеУчетныеЗаписи = РаботаСПочтовымиСообщениями.ДоступныеУчетныеЗаписи(Истина);

Если ДоступныеУчетныеЗаписи.Количество() = 0 Тогда

ТекстСообщения = НСтр("ru = 'Не обнаружены доступные учетные записи электронной почты, обратитесь к администратору системы.'");

ОбщегоНазначения.СообщитьПользователю(ТекстСообщения,,,,Отказ);

Возврат;

КонецЕсли;

27. [**СистемнаяУчетнаяЗапись**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Ho8fLl7O3g//P35fLt4P/n4O/o8fwuaHRtIw==). Получает ссылку на учетную запись по виду назначения учетной записи.

Результат = РаботаСПочтовымиСообщениями.СистемнаяУчетнаяЗапись()

ОтправительEmail = Результат.АдресЭлектроннойПочты;

//

УчетнаяЗапись = РаботаСПочтовымиСообщениями.СистемнаяУчетнаяЗапись();

Попытка

Профиль = РаботаСПочтовымиСообщениямиСлужебный.ИнтернетПочтовыйПрофиль(УчетнаяЗапись);

Соединение = Новый ИнтернетПочта;

Соединение.Подключиться(Профиль);

Исключение

СообщениеОбОшибке = СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(

НСтр("ru = 'Не удалось установить соединение с почтовым сервером: (%1)'"), ОписаниеОшибки());

Возврат;

КонецПопытки;

//

11. [**УчетнаяЗаписьНастроена**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/P35fLt4P/n4O/o8fzt4PHy8O7l7eAuaHRtIw==). Проверяет, настроена ли учетная запись для отправки и/или получения почты.

Результат = РаботаСПочтовымиСообщениями.УчетнаяЗаписьНастроена(УчетнаяЗапись, ДляОтправки, ДляПолучения)

16. [**ПроверитьНаличиеУчетнойЗаписиДляОтправкиПочты**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/w7uLl8Ojy/O3g6+j36OXz9+Xy7e7p5+Dv6PHo5Ov/7vLv8ODi6ujv7vfy+y5odG0j). Если у пользователя нет настроенной учетной записи для отправки писем, то в зависимости от прав либо показывает помощник настройки новой учетной записи, либо выводит сообщение о невозможности отправки.

РаботаСПочтовымиСообщениямиКлиент.ПроверитьНаличиеУчетнойЗаписиДляОтправкиПочты(ОбработчикРезультата)

//

&НаКлиенте

Процедура НачатьПроверкуУчетнойЗаписи()

РаботаСПочтовымиСообщениямиКлиент.ПроверитьНаличиеУчетнойЗаписиДляОтправкиПочты(

Новый ОписаниеОповещения("ЗавершитьПроверкуУчетнойЗаписи", ЭтотОбъект));

КонецПроцедуры

&НаКлиенте

Процедура ЗавершитьПроверкуУчетнойЗаписи(Результат, ДополнительныеПараметры) Экспорт

Если Результат = Истина Тогда

ЗаполнитьУчетнуюЗапись();

Возврат;

КонецЕсли;

ПоказатьПредупреждение(Новый ОписаниеОповещения("ЗавершитьРаботуФормы", ЭтотОбъект),

НСтр("ru = 'Для рассылки документов требуется настроенная для отправки учетная запись электронной почты."));

КонецПроцедуры

23. [**ДоступнаОтправкаПисем**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+Tu8fLz7+3g7vLv8ODi6uDv6PHl7C5odG0j). Возвращает Истина, если доступна по меньшей мере одна настроенная учетная запись для отправки почты либо достаточно прав на настройку учетной записи.

Результат = РаботаСПочтовымиСообщениями.ДоступнаОтправкаПисем()

//

Если Не РаботаСПочтовымиСообщениями.ДоступнаОтправкаПисем() Тогда

Возврат НСтр("ru = 'Нет прав на отправку писем или нет доступных учетных записей.'");

КонецЕсли;

27. [**ПодготовитьПисьмо**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/u5OPu8u7i6PL87+jx/OzuLmh0bSM=). Формирует письмо по переданным параметрам.

Результат = РаботаСПочтовымиСообщениями.ПодготовитьПисьмо(УчетнаяЗапись, ПараметрыПисьма)

//

ПараметрыОтправки = Новый Структура();

ПараметрыОтправки.Вставить("Кому", АдресКонтрагента);

ПараметрыОтправки.Вставить("Тема", Тема);

ПараметрыОтправки.Вставить("Тело", );

ПараметрыОтправки.Вставить("Вложения", Вложения);

Письмо = РаботаСПочтовымиСообщениями.ПодготовитьПисьмо(РеквизитыПакетаЭД.АдресРесурсаОрганизации, ПараметрыОтправки);

24. [**ОтправитьПисьмо**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7y7/Dg4ujy/O/o8fzs7i5odG0j). Выполняет отправку одного письма. Функция может вызвать исключение, которое требуется обработать.

Результат = РаботаСПочтовымиСообщениями.ОтправитьПисьмо(УчетнаяЗапись, Письмо)

//

Функция ОтправитьПакетЧерезЭлектроннуюПочту(ПараметрыОтправки, КонтекстОперации)

Вложения = Новый Массив;

ФайлыДляОтправки = НайтиФайлы(АдресКаталогаОтправки, "\*.zip");

Для Каждого Файл Из ФайлыДляОтправки Цикл

ОписаниеВложения = Новый Структура;

ОписаниеВложения.Вставить("Представление", Файл.Имя);

ОписаниеВложения.Вставить("АдресВоВременномХранилище",

ПоместитьВоВременноеХранилище(Новый ДвоичныеДанные(Файл.ПолноеИмя)));

Вложения.Добавить(ОписаниеВложения);

КонецЦикла;

ПараметрыОтправки = Новый Структура();

ПараметрыОтправки.Вставить("Кому", АдресКонтрагента);

ПараметрыОтправки.Вставить("Тема", Тема);

ПараметрыОтправки.Вставить("Тело", );

ПараметрыОтправки.Вставить("Вложения", Вложения);

Письмо = РаботаСПочтовымиСообщениями.ПодготовитьПисьмо(РеквизитыПакетаЭД.АдресРесурсаОрганизации, ПараметрыОтправки);

Попытка

РаботаСПочтовымиСообщениями.ОтправитьПисьмо(РеквизитыПакетаЭД.АдресРесурсаОрганизации, Письмо);

РезультатОтправки = Истина;

Исключение

ТекстОшибки = СтрШаблон(НСтр("ru = 'Не удалось отправить письмо по адресу %1'"), АдресКонтрагента);

КонецПопытки;

Возврат РезультатОтправки;

КонецФункции

12. [**СоздатьНовоеПисьмо**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Hu5+Tg8vzt7uLu5e/o8fzs7i5odG0j). Открывает форму создания нового письма.

РаботаСПочтовымиСообщениямиКлиент.СоздатьНовоеПисьмо(ПараметрыОтправкиПисьма, ОповещениеОЗакрытииФормы)

//

Процедура ОтправитьОтчет(Отчет, ДополнительныеПараметры = Неопределено) Экспорт

ПараметрыОтчета = Новый Структура;

ПараметрыОтчета.Вставить("ТабличныйДокумент", Отчет.Результат);

ПараметрыОтчета.Вставить("Заголовок" , Отчет.Заголовок);

КлючеваяОперация = "ОтправкаОтчетаПоЭлектроннойПочте";

ОценкаПроизводительностиКлиент.НачатьЗамерВремени(Истина, КлючеваяОперация);

ПараметрыПисьма = ОтправкаПочтовыхСообщенийВызовСервера.ПараметрыЭлектронногоПисьмаДляОтчетов(ПараметрыОтчета,

ДополнительныеПараметры);

РаботаСПочтовымиСообщениямиКлиент.СоздатьНовоеПисьмо(ПараметрыПисьма);

КонецПроцедуры

9. [**ОтправитьПисьма**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7y7/Dg4ujy/O/o8fzs4C5odG0j). Выполняет отправку нескольких писем.

Результат = РаботаСПочтовымиСообщениями.ОтправитьПисьма(УчетнаяЗапись, Письма, ТекстОшибки)

//

Письма = Новый Массив;

Для Каждого КлючИЗначение Из ПараметрыДоставки.Получатели Цикл

ПараметрыПисьма.Тело = СтрЗаменить(ШаблонТекста, "[Получатель]", Строка(КлючИЗначение.Ключ));

ПараметрыПисьма.Вставить(КлючАдресаДоставки, КлючИЗначение.Значение);

Письма.Добавить(ПодготовитьПисьмо(ПараметрыДоставки, ПараметрыПисьма));

КонецЦикла;

РаботаСПочтовымиСообщениями.ОтправитьПисьма(ПараметрыДоставки.УчетнаяЗапись, Письма);

8. [**ЗагрузитьПочтовыеСообщения**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+fg4/Dz5+jy/O/u9/Lu4vvl8e7u4fnl7ej/Lmh0bSM=). Загружает сообщения с сервера электронной почты для указанной учетной записи.

Результат = РаботаСПочтовымиСообщениями.ЗагрузитьПочтовыеСообщения(УчетнаяЗапись, ПараметрыЗагрузки)

//

Функция ЗагрузитьПочтовыеСообщенияПоЭДО(РесурсОбмена)

ПараметрыЗагрузкиЗаголовков = Новый Структура;

ПараметрыЗагрузкиЗаголовков.Вставить("ПолучениеЗаголовков", Истина);

ПараметрыЗагрузкиЗаголовков.Вставить("ПриводитьСообщенияКТипу", Ложь);

НаборСообщений = РаботаСПочтовымиСообщениями.ЗагрузитьПочтовыеСообщения(

РесурсОбмена.УчетнаяЗаписьЭлектроннойПочты, ПараметрыЗагрузкиЗаголовков);

Если Не ЗначениеЗаполнено(НаборСообщений) Тогда

Возврат НаборСообщений;

КонецЕсли;

Для Каждого Сообщение Из НаборСообщений Цикл

АдресОтправителя = НРег(?(ТипЗнч(Сообщение.Отправитель) = Тип("Строка"),

Сообщение.Отправитель, Сообщение.Отправитель.Адрес));

КонецЦикла;

Возврат НаборСообщений

КонецФункции

6. [**ПараметрыОтправкиПисьма**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+/g8ODs5fLw++7y7/Dg4uro7+jx/OzgLmh0bSM=). Возвращает пустую структуру с параметрами отправки письма.

Результат = РаботаСПочтовымиСообщениямиКлиент.ПараметрыОтправкиПисьма()

4. [**ЕстьВнешниеРесурсы**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+Xx8vzi7eX47ejl8OXx8/Dx+y5odG0j). Проверяет наличие в документе HTML ссылок на ресурсы, загружаемые по http(s).

Результат = РаботаСПочтовымиСообщениями.ЕстьВнешниеРесурсы(ДокументHTML)

//

Процедура ОтфильтроватьСодержимоеТекстаHTML(ТекстHTML, Кодировка = Неопределено,

ОтключитьВнешниеРесурсы = Истина, ЕстьВнешниеРесурсы = Неопределено) Экспорт

ДокументHTML = ПолучитьОбъектДокументHTMLИзТекстаHTML(ТекстHTML, Кодировка);

ЕстьВнешниеРесурсы = РаботаСПочтовымиСообщениями.ЕстьВнешниеРесурсы(ДокументHTML);

РаботаСПочтовымиСообщениями.ОтключитьНебезопасноеСодержимое(ДокументHTML, ЕстьВнешниеРесурсы И ОтключитьВнешниеРесурсы);

ТекстHTML = ПолучитьТекстHTMLИзОбъектаДокументHTML(ДокументHTML);

КонецПроцедуры

4. [**ОтключитьНебезопасноеСодержимое**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7y6uv+9+jy/O3l4eXn7u/g8e3u5fHu5OXw5ujs7uUuaHRtIw==). Удаляет из документа HTML скрипты, обработчики событий, а также очищает ссылки на ресурсы, загружаемые по http(s).

РаботаСПочтовымиСообщениями.ОтключитьНебезопасноеСодержимое(ДокументHTML, ОтключитьВнешниеРесурсы)

//

Процедура ОтфильтроватьСодержимоеТекстаHTML(ТекстHTML, Кодировка = Неопределено,

ОтключитьВнешниеРесурсы = Истина, ЕстьВнешниеРесурсы = Неопределено) Экспорт

ДокументHTML = ПолучитьОбъектДокументHTMLИзТекстаHTML(ТекстHTML, Кодировка);

ЕстьВнешниеРесурсы = РаботаСПочтовымиСообщениями.ЕстьВнешниеРесурсы(ДокументHTML);

РаботаСПочтовымиСообщениями.ОтключитьНебезопасноеСодержимое(ДокументHTML, ЕстьВнешниеРесурсы И ОтключитьВнешниеРесурсы);

ТекстHTML = ПолучитьТекстHTMLИзОбъектаДокументHTML(ДокументHTML);

КонецПроцедуры

**Отправка SMS**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6Mjg3Omhkb2M=)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQwJUJFJUQxJTgyJUQwJUJGJUQxJTgwJUQwJUIwJUQwJUIyJUQwJUJBJUQwJUIwX3Ntcw==)

23. [**НастройкаОтправкиSMSВыполнена**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+3g8fLw7unq4O7y7/Dg4uroc21z4vvv7uvt5e3gLmh0bSM=). Проверяет правильность сохраненных настроек отправки SMS.

Результат = ОтправкаSMS.НастройкаОтправкиSMSВыполнена()

//

Если Не ОтправкаSMS.НастройкаОтправкиSMSВыполнена() Тогда

РезультатОтправки.Ошибка = Истина;

РезультатОтправки.ТекстОшибки = НСтр("ru = 'Ошибка при отправке SMS: не выполнена настройка отправки.'");

Возврат РезультатОтправки;

КонецЕсли;

12. [**ОтправитьSMS**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+7y7/Dg4ujy/HNtcy5odG0j). Для вызова с клиента: Открывает форму для отправки нового SMS. Для вызова с сервера: Отправляет SMS через настроенного поставщика услуги, возвращает идентификатор сообщения.

ОтправкаSMSКлиент.ОтправитьSMS(НомераПолучателей, Текст, ДополнительныеПараметры)

4. [**СтатусДоставки**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Hy4PLz8eTu8fLg4uroLmh0bSM=). Запрашивает статус доставки сообщения у поставщика услуг.

Результат = ОтправкаSMS.СтатусДоставки(ИдентификаторСообщения)

0. [**ДоступнаОтправкаSMS**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+Tu8fLz7+3g7vLv8ODi6uBzbXMuaHRtIw==). Проверяет возможность отправки SMS для текущего пользователя.

Результат = ОтправкаSMS.ДоступнаОтправкаSMS()

**Оценка производительности**

[Пользовательская документация](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6Mjg4Omhkb2M=)

[Настройка и использование](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvYnNwMzE0ZG9jI2NvbnRlbnQ6NDoxOmlzc29nbDFfJUQwJUJFJUQxJTg2JUQwJUI1JUQwJUJEJUQwJUJBJUQwJUIwXyVEMCVCRiVEMSU4MCVEMCVCRSVEMCVCOCVEMCVCNyVEMCVCMiVEMCVCRSVEMCVCNCVEMCVCOCVEMSU4MiVEMCVCNSVEMCVCQiVEMSU4QyVEMCVCRCVEMCVCRSVEMSU4MSVEMSU4MiVEMCVCOA==)

1282. [**ЗамерВремени**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+fg7OXw4vDl7OXt6C5odG0j). Начинает замер времени ключевой операции. Результат замера будет записан в регистр сведений ЗамерыВремени.

Результат = ОценкаПроизводительностиКлиент.ЗамерВремени(КлючеваяОперация, ФиксироватьСОшибкой, АвтоЗавершение)

//

УИДЗамера = ОценкаПроизводительностиКлиент.ЗамерВремени("Обработка.ВыполнениеОпераций.Форма.ОбновитьДанные",, Ложь);

47. [**ЗавершитьЗамерВремени**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+fg4uXw+Ojy/Ofg7OXw4vDl7OXt6C5odG0j). Завершает замер времени на клиенте.

ОценкаПроизводительностиКлиент.ЗавершитьЗамерВремени(УИДЗамера, ВыполненСОшибкой)

//

&НаКлиенте

Процедура ОбновитьДанные()

УИДЗамера = ОценкаПроизводительностиКлиент.ЗамерВремени("Обработка.ВыполнениеОперацийФорма.ОбновитьДанные",, Ложь);

ЗаполнитьДанныеВнутриЗамераВремени();

ОценкаПроизводительностиКлиент.ЗавершитьЗамерВремени(УИДЗамера);

КонецПроцедуры

154. [**НачатьЗамерВремени**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+3g9+Dy/Ofg7OXw4vDl7OXt6C5odG0j). Начинает замер времени ключевой операции. Закончить замер нужно явно вызовом процедуры ЗакончитьЗамерВремени или ЗакончитьЗамерВремениТехнологический.

Результат = ОценкаПроизводительности.НачатьЗамерВремени()

//

Функция ОперацииПоЯндексКассе(Знач ВходящиеПараметры) Экспорт

ВремяНачала = ОценкаПроизводительности.НачатьЗамерВремени();

КлючеваяОперация = "ИнтеграцияСЯндексКассой.ПолучениеОперацийПоЯндексКассе";

КоличествоПовторяющихсяДанных = 0;

Для каждого ПараметрыПолучения Из ПараметрыПолученияОпераций Цикл

КоличествоПовторяющихсяДанных = КоличествоПовторяющихсяДанных + 1;

...

КонецЦикла;

ОценкаПроизводительности.ЗакончитьЗамерВремени(КлючеваяОперация, ВремяНачала, КоличествоПовторяющихсяДанных);

КонецФункции

119. [**ЗакончитьЗамерВремени**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+fg6u7t9+jy/Ofg7OXw4vDl7OXt6C5odG0j). Завершает замер времени ключевой операции и записывает результат в регистр сведений ЗамерыВремени.

ОценкаПроизводительности.ЗакончитьЗамерВремени(КлючеваяОперация, ВремяНачала, ВесЗамера, Комментарий, ВыполненСОшибкой)

//

&НаСервере

Процедура ПриЗаписиНаСервере(Отказ, ТекущийОбъект, ПараметрыЗаписи)

ВремяНачала = ОценкаПроизводительности.НачатьЗамерВремени();

УчетРабочегоВремениРасширенный.ЗаписатьДанныеГрафика(

ТекущийОбъект.Ссылка, ДанныеГрафика, НомерТекущегоГода,

НЕ СреднемесячныеНормыВремениГрафиковРаботыСотрудников.УстановленыВРучную, Ложь);

ОценкаПроизводительности.ЗакончитьЗамерВремени(

"ЗаписьЭлементаСправочникаГрафикиРаботыСотрудников",

ВремяНачала);

КонецПроцедуры

313. [**НачатьЗамерДлительнойОперации**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+3g9+Dy/Ofg7OXw5Ovo8uXr/O3u6e7v5fDg9ujoLmh0bSM=). Начинает замер времени выполнения длительной ключевой операции. Закончить замер нужно явно вызовом процедуры ЗакончитьЗамерДлительнойОперации.

Результат = ОценкаПроизводительностиКлиент.НачатьЗамерДлительнойОперации(КлючеваяОперация, ФиксироватьСОшибкой, АвтоЗавершение, ИмяПоследнегоШага)

//

Процедура ВыполнитьКлиентскуюДиагностику(ПараметрыВыполнения)

Замер = ОценкаПроизводительностиКлиент.НачатьЗамерДлительнойОперации(

"ОбщийМодуль.ОбменСКонтрагентамиДиагностикаКлиент.ВыполнитьКлиентскуюДиагностику");

ПараметрыВыполнения.ЗамерДиагностикиНаКлиенте = Замер;

Контекст = Новый Структура;

Контекст.Вставить("ПараметрыВыполнения", ПараметрыВыполнения);

ОбработчикЗавершения = Новый ОписаниеОповещения("ПослеВыполненияКлиентскойДиагностики", ЭтотОбъект);

Обработчики = Новый Массив;

Обработчики.Добавить(Новый ОписаниеОповещения("ДиагностикаКриптографии", ЭтотОбъект, Контекст));

Обработчики.Добавить(Новый ОписаниеОповещения("ТестАутентификации", ЭтотОбъект, Контекст));

АсинхронныйЦиклНачать(ОбработчикЗавершения, Неопределено, Обработчики, Контекст);

КонецПроцедуры

Процедура ПослеВыполненияКлиентскойДиагностики(Контекст, ДополнительныеПараметры = Неопределено) Экспорт

..

ОценкаПроизводительностиКлиент.ЗакончитьЗамерДлительнойОперации(Контекст.ПараметрыВыполнения.ЗамерДиагностикиНаКлиенте, 1);

КонецПроцедуры

333. [**ЗакончитьЗамерДлительнойОперации**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+fg6u7t9+jy/Ofg7OXw5Ovo8uXr/O3u6e7v5fDg9ujoLmh0bSM=). Завершает замер длительной операции. Для вызова с клиента модуль - ОценкаПроизводительностиКлиент.

ОценкаПроизводительностиКлиент.ЗакончитьЗамерДлительнойОперации(ОписаниеЗамера, КоличествоДанных, ИмяШага, Комментарий)

//

Процедура ПостроитьДеревоСебестоимости(ПараметрыДерева, ПараметрыУзла = Неопределено) Экспорт

Замер = ОценкаПроизводительности.НачатьЗамерДлительнойОперации("ОбщийМодуль.СтруктураСебестоимости.ПостроитьДеревоСебестоимости");

ПараметрыДерева.Вставить("КоличествоСтрок", 0);

ЗаполнитьДеревоСебестоимости(ПараметрыДерева, ПараметрыУзла);

ОценкаПроизводительности.ЗакончитьЗамерДлительнойОперации(Замер, ПараметрыДерева.КоличествоСтрок / 1000);

КонецПроцедуры

248. [**ЗафиксироватьЗамерДлительнойОперации**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL+fg9Ojq8ejw7uLg8vzn4Ozl8OTr6PLl6/zt7unu7+Xw4Pbo6C5odG0j). Фиксирует замер вложенного шага длительной операции.

ОценкаПроизводительностиКлиент.ЗафиксироватьЗамерДлительнойОперации(ОписаниеЗамера, КоличествоДанных, ИмяШага, Комментарий)

49. [**УстановитьКлючевуюОперациюЗамера**](https://infostart.ru/redirect.php?url=aHR0cHM6Ly9pdHMuMWMucnUvZGIvY29udGVudC9ic3AzMTRkb2Mvc3JjL/Px8uDt7uLo8vzq6/735eLz/u7v5fDg9uj+5+Ds5fDgLmh0bSM=). Устанавливает ключевую операцию замера.

ОценкаПроизводительностиКлиент.УстановитьКлючевуюОперациюЗамера(УИДЗамера, КлючеваяОперация)

//

&НаКлиенте

Процедура ПослеЗаписи(ПараметрыЗаписи)

Если ПараметрыЗаписи.РежимЗаписи = РежимЗаписиДокумента.Проведение Тогда

ОценкаПроизводительностиКлиент.УстановитьКлючевуюОперациюЗамера(ИдентификаторЗамераПроведениеНеНужнаРегистрацияОшибки,

"ПроведениеДокументаИндивидуальныйГрафик");

КонецЕсли;

КонецПроцедуры